From f35386817c902715cc762c392403c5aee79928cc Mon Sep 17 00:00:00 2001
From: Michael Palimaka <kensington@gentoo.org>
Date: Mon, 21 Dec 2015 05:30:35 +1100
Subject: net-libs/signond: version bump

Package-Manager: portage-2.2.26
---
 net-libs/signond/Manifest            |  1 +
 net-libs/signond/signond-8.58.ebuild | 58 ++++++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)
 create mode 100644 net-libs/signond/signond-8.58.ebuild

(limited to 'net-libs')

diff --git a/net-libs/signond/Manifest b/net-libs/signond/Manifest
index e9e947a305bd..744e61a5e9ae 100644
--- a/net-libs/signond/Manifest
+++ b/net-libs/signond/Manifest
@@ -1 +1,2 @@
 DIST signon-8.57.tar.bz2 197988 SHA256 239a2c6bb39c338402d9ae29287fbc439f422f82e7e6d060be23104173620bee SHA512 98bdee0b15fbc0ade1158df95f727ba56ae2966117d8ce7074b4f355dc3be0db27ab52340654da8ab4324e6d8d160c65802e1bed295ac3ad02ddc720581bbdb3 WHIRLPOOL e7bc4f31e2d59ce361b45c77f0eb838e601bf55e24e53413fec3ec91feaec7fad85581b1dba80cb9350584a10822202af748e74f46bc06dc96b2aeff52bf105b
+DIST signond-8.58.tar.gz 277287 SHA256 301e2e3b6919585c8ffc56f73ec1f0f9b18a533e1db88461e9fa4e2acf75a34a SHA512 74c9f32ea99c869c0aa72b5816962336869131ea4e8484c53636b35f2ed669a49cbc0ccf10c2c446697892235b94cf2c74f8d5402f430081d7d51421646eec91 WHIRLPOOL 7cff41e9ca37627a6a80a3c23d960958543ee2344ee24771d5e02c6a519d82f68a5003bf9a2bb413c9cbf20f7b450adaf9a82160cd422146431fce237d87d084
diff --git a/net-libs/signond/signond-8.58.ebuild b/net-libs/signond/signond-8.58.ebuild
new file mode 100644
index 000000000000..9343cf8f51f0
--- /dev/null
+++ b/net-libs/signond/signond-8.58.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit qmake-utils vcs-snapshot
+
+DESCRIPTION="Signon daemon for libaccounts-glib"
+HOMEPAGE="https://01.org/gsso/"
+SRC_URI="https://gitlab.com/accounts-sso/signond/repository/archive.tar.gz?ref=VERSION_8.58 -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RESTRICT="test"
+
+# libproxy[kde] results in segfaults due to symbol collisions with qt4
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	net-libs/libproxy[-kde]
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( dev-qt/qttest:5 )
+"
+
+src_prepare() {
+	# ensure qt5 version of binary is used
+	sed -e "s|qdbusxml2cpp|$(qt5_get_bindir)/&|" -i src/signond/signond.pro || die
+
+	# install docs to correct location
+	sed -e "s|share/doc/\$\${PROJECT_NAME}|share/doc/${PF}|" -i doc/doc.pri || die
+
+	# don't install example plugin
+	sed -e "/example/d" -i src/plugins/plugins.pro || die
+
+	# make tests optional
+	use test || sed -i -e '/^SUBDIRS/s/tests//' signon.pro || die "couldn't disable tests"
+
+	# make docs optional
+	use doc || sed -e "/include(\s*doc\/doc.pri\s*)/d" -i \
+		signon.pro -i lib/SignOn/SignOn.pro lib/plugins/plugins.pro || die
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+}
-- 
cgit v1.2.3-65-gdbad