From 1cdd5937af974cd53b9ee5b138031a310d5ab265 Mon Sep 17 00:00:00 2001
From: Ionen Wolkens <ionen@gentoo.org>
Date: Sun, 20 Nov 2022 20:52:57 -0500
Subject: games-emulation/desmume: fix w/ clang16, filter-lto + -fno-strict

Looking a bit fragile for LTO overall, so haven't looked
into doing proper fixes.

Also GPL-2 -> GPL-2+

Closes: https://bugs.gentoo.org/858629
Closes: https://bugs.gentoo.org/874996
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
---
 games-emulation/desmume/desmume-0.9.13-r1.ebuild | 58 ++++++++++++++++++++++++
 games-emulation/desmume/desmume-0.9.13.ebuild    | 55 ----------------------
 2 files changed, 58 insertions(+), 55 deletions(-)
 create mode 100644 games-emulation/desmume/desmume-0.9.13-r1.ebuild
 delete mode 100644 games-emulation/desmume/desmume-0.9.13.ebuild

(limited to 'games-emulation/desmume')

diff --git a/games-emulation/desmume/desmume-0.9.13-r1.ebuild b/games-emulation/desmume/desmume-0.9.13-r1.ebuild
new file mode 100644
index 000000000000..105f0464ab1c
--- /dev/null
+++ b/games-emulation/desmume/desmume-0.9.13-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic meson xdg
+
+DESCRIPTION="Nintendo DS emulator"
+HOMEPAGE="https://desmume.org/"
+SRC_URI="https://github.com/TASEmulators/desmume/releases/download/release_$(ver_rs 1- _)/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gdb +gui openal wifi"
+
+RDEPEND="
+	dev-libs/glib:2
+	media-libs/libsdl2[X,opengl,sound,video]
+	media-libs/libsoundtouch:=
+	net-libs/libpcap
+	sys-libs/zlib:=
+	x11-libs/agg
+	x11-libs/libX11
+	gui? (
+		media-libs/libglvnd[X]
+		x11-libs/cairo
+		x11-libs/gdk-pixbuf:2
+		x11-libs/gtk+:3
+	)
+	openal? ( media-libs/openal )
+	!openal? ( media-libs/alsa-lib )"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9.11_p20210409-fix-gtk-cliopts.patch
+	"${FILESDIR}"/${PN}-0.9.11_p20210409-openal-automagic.patch
+)
+
+DOCS=( ${PN}/{AUTHORS,ChangeLog,README,README.LIN,doc/.} )
+
+src_configure() {
+	append-flags -fno-strict-aliasing #858629
+	append-cppflags -D_XOPEN_SOURCE=500 #874996
+	filter-lto # odr issues
+
+	local EMESON_SOURCE=${S}/${PN}/src/frontend/posix
+	local emesonargs=(
+		$(meson_use gdb gdb-stub)
+		$(meson_use gui frontend-gtk)
+		$(meson_use openal)
+		$(meson_use wifi)
+	)
+
+	meson_src_configure
+}
diff --git a/games-emulation/desmume/desmume-0.9.13.ebuild b/games-emulation/desmume/desmume-0.9.13.ebuild
deleted file mode 100644
index f4edfb4b5a3e..000000000000
--- a/games-emulation/desmume/desmume-0.9.13.ebuild
+++ /dev/null
@@ -1,55 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit meson xdg
-
-DESCRIPTION="Nintendo DS emulator"
-HOMEPAGE="https://desmume.org/"
-SRC_URI="https://github.com/TASEmulators/desmume/releases/download/release_$(ver_rs 1- _)/${P}.tar.xz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="gdb +gui openal wifi"
-
-RDEPEND="
-	dev-libs/glib:2
-	media-libs/libsdl2[X,opengl,sound,video]
-	media-libs/libsoundtouch:=
-	net-libs/libpcap
-	sys-libs/zlib:=
-	x11-libs/agg
-	x11-libs/libX11
-	gui? (
-		media-libs/libglvnd[X]
-		x11-libs/cairo
-		x11-libs/gdk-pixbuf:2
-		x11-libs/gtk+:3
-	)
-	openal? ( media-libs/openal )
-	!openal? ( media-libs/alsa-lib )"
-DEPEND="
-	${RDEPEND}
-	x11-base/xorg-proto"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.9.11_p20210409-fix-gtk-cliopts.patch
-	"${FILESDIR}"/${PN}-0.9.11_p20210409-openal-automagic.patch
-)
-
-DOCS=( ${PN}/{AUTHORS,ChangeLog,README,README.LIN,doc/.} )
-
-src_configure() {
-	local EMESON_SOURCE=${S}/${PN}/src/frontend/posix
-
-	local emesonargs=(
-		$(meson_use gdb gdb-stub)
-		$(meson_use gui frontend-gtk)
-		$(meson_use openal)
-		$(meson_use wifi)
-	)
-
-	meson_src_configure
-}
-- 
cgit v1.2.3-65-gdbad