From ccf0ae60e329c0a461443d1741d359f8c90bbaac Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Fri, 26 Oct 2018 10:26:06 +0200
Subject: dev-vcs/gitg: Bump to 0.30.1, now using meson
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-vcs/gitg/Manifest           |  1 +
 dev-vcs/gitg/gitg-3.30.1.ebuild | 92 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 93 insertions(+)
 create mode 100644 dev-vcs/gitg/gitg-3.30.1.ebuild

(limited to 'dev-vcs/gitg')

diff --git a/dev-vcs/gitg/Manifest b/dev-vcs/gitg/Manifest
index fe3406baeee4..3f72ce9e834b 100644
--- a/dev-vcs/gitg/Manifest
+++ b/dev-vcs/gitg/Manifest
@@ -1 +1,2 @@
 DIST gitg-3.26.0.tar.xz 1551308 BLAKE2B 45a9fd3df8eb891c4e07eefb6cf8f9b517c78dccc63dd08498b4c847614e164472e0605a01c81515ea349366e56c21c99a4558e73b6548b18bb94f578c0fc9bd SHA512 782aa02e2f0f4d8c86ad726045502d545877d835f0449d2ec646d93a78bbfa50f84662d3a437c922eb168b2737c00ec088dc2c73487742f332e3910f041b519d
+DIST gitg-3.30.1.tar.xz 10555888 BLAKE2B 02e8f957eee82bbf0702ca39b5b336929c131a93a94f5e28a2e4aa7c2c473c5d8bda072eba184cef37d6ad2fa7bfa21c007c86204a0a81b6d401487d752952fd SHA512 0d9241422dda6bf1840632fbcabf6b640554081ba995eba59ce90f893654e42c0ca8953e814533b90f362abb13b002e7a74b5f6841aee1f33c2834d2acab869f
diff --git a/dev-vcs/gitg/gitg-3.30.1.ebuild b/dev-vcs/gitg/gitg-3.30.1.ebuild
new file mode 100644
index 000000000000..8b455c5215f3
--- /dev/null
+++ b/dev-vcs/gitg/gitg-3.30.1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+VALA_MIN_API_VERSION="0.32" # Needed when gtk+-3.20 is found
+
+inherit gnome.org gnome2-utils meson python-r1 vala xdg-utils
+
+DESCRIPTION="git repository viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gitg"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="glade +python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# test if unbundling of libgd is possible
+# Currently it seems not to be (unstable API/ABI)
+RDEPEND="
+	app-crypt/libsecret[vala]
+	>=app-text/gtkspell-3.0.3:3[vala]
+	>=dev-libs/glib-2.38:2[dbus]
+	>=dev-libs/gobject-introspection-0.10.1:=
+	dev-libs/libgee:0.8[introspection]
+	dev-libs/libgit2:=[threads]
+
+	>=dev-libs/libgit2-glib-0.26.4[ssh]
+	<dev-libs/libgit2-glib-0.27.0
+
+	>=dev-libs/libpeas-1.5.0[gtk]
+	>=dev-libs/libxml2-2.9.0:2
+	>=gnome-base/gsettings-desktop-schemas-0.1.1
+	net-libs/libsoup:2.4
+	>=x11-libs/gtk+-3.20.0:3
+	>=x11-libs/gtksourceview-3.10:3.0
+	x11-themes/adwaita-icon-theme
+	glade? ( >=dev-util/glade-3.2:3.10 )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	>=dev-libs/libgit2-glib-0.24.4[vala]
+	>=dev-util/intltool-0.40
+	gnome-base/gnome-common
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && [[ ${MERGE_TYPE} != binary ]] && python_setup
+}
+
+src_prepare() {
+	default
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dglade_catalog=$(usex glade true false)
+		# we install the module manually anyway
+		-Dpython=false
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use python ; then
+		python_moduleinto gi.overrides
+		python_foreach_impl python_domodule libgitg-ext/GitgExt.py
+	fi
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3-65-gdbad