From dd2356d9e32dc095fcb1ab9144bf0ce7a52dbe66 Mon Sep 17 00:00:00 2001
From: Matthew Thode <prometheanfire@gentoo.org>
Date: Fri, 16 Feb 2018 19:34:43 -0600
Subject: dev-python/webtest: 2.0.29 bup

Package-Manager: Portage-2.3.19, Repoman-2.3.6
---
 dev-python/webtest/Manifest              |  1 +
 dev-python/webtest/webtest-2.0.29.ebuild | 66 ++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)
 create mode 100644 dev-python/webtest/webtest-2.0.29.ebuild

(limited to 'dev-python/webtest')

diff --git a/dev-python/webtest/Manifest b/dev-python/webtest/Manifest
index cc3380a64e5f..87d4771de373 100644
--- a/dev-python/webtest/Manifest
+++ b/dev-python/webtest/Manifest
@@ -1 +1,2 @@
 DIST WebTest-2.0.21.tar.gz 66866 BLAKE2B d2830fcce7fb4b91029838806952e3e9c6916c3b292c7142138f30486d936b4a1f0c2d28a5973b0c351c64e499f343f3711296c6e37c38548e3a81b108163a17 SHA512 21f58ee9192fd0eb0eb2d88179ffc015aa5cf04c8004db251bd65d13d54c34b9e6b5fc9fdd8e9fcbbc18fcfb2be714c0691b2ef034318861262f8705b4a44610
+DIST WebTest-2.0.29.tar.gz 74620 BLAKE2B 7fc68f1178b1abb0a0f126112b846853762ad78cb060718bc340f5ba17517180b7283f384503ff77a2c7396645ebe2d5528dbc0f027c5d44beb002c4204bf894 SHA512 319700d1444f6a681f8ed8a4ee8661ba0462b3f4bfeb7510232f58be92e017066da3bac494ebe1a3c5b9f2d06c025e08e6193277e13c6113e9485108d4ccd2d2
diff --git a/dev-python/webtest/webtest-2.0.29.ebuild b/dev-python/webtest/webtest-2.0.29.ebuild
new file mode 100644
index 000000000000..b30ffa8e4a34
--- /dev/null
+++ b/dev-python/webtest/webtest-2.0.29.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1
+
+MY_PN="WebTest"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Helper to test WSGI applications"
+HOMEPAGE="http://pythonpaste.org/webtest/ https://pypi.python.org/pypi/WebTest"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="doc test"
+
+# nose<1.3.0 appears a leftover never updated in requires.txt. tests pass fine with latest
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.2[${PYTHON_USEDEP}]
+	>=dev-python/waitress-0.8.5[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pyquery[${PYTHON_USEDEP}]
+		dev-python/pastedeploy[${PYTHON_USEDEP}]
+		dev-python/wsgiproxy2[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 )
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+# Makes testing easier; otherwise we get errors from pkg_resources.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Prevent un-needed d'loading during doc build
+	sed -s 's:intersphinx_mapping:_&:' -i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs html || die
+	fi
+}
+
+python_test() {
+	# Tests raise ImportErrors with our default PYTHONPATH.
+	local -x PYTHONPATH=
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( html/. )
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad