From e1e6f0bab36d6bbb391620fa5c414f6508f8d243 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Tue, 21 Jun 2022 06:34:18 +0100
Subject: dev-python/reflink: drop broken PEP517

Need to unlock Beets.

Closes: https://bugs.gentoo.org/850442
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-python/reflink/reflink-0.2.1-r3.ebuild | 47 ++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-python/reflink/reflink-0.2.1-r3.ebuild

(limited to 'dev-python/reflink')

diff --git a/dev-python/reflink/reflink-0.2.1-r3.ebuild b/dev-python/reflink/reflink-0.2.1-r3.ebuild
new file mode 100644
index 000000000000..74551647eaea
--- /dev/null
+++ b/dev-python/reflink/reflink-0.2.1-r3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_IN_SOURCE_BUILD=1
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python wrapper around the reflink system calls"
+HOMEPAGE="https://gitlab.com/rubdos/pyreflink"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+RDEPEND="virtual/python-cffi[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="${RDEPEND}
+	test? ( sys-fs/btrfs-progs )
+"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -e 's|'\''pytest-runner'\'',\?||' -i setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local notestmsg="Tests need FEATURES='-usersandbox -userpriv -sandbox'"
+	if [[ ${EUID} != 0 ]]; then
+		ewarn "${notestmsg}"
+	elif
+		has sandbox ${FEATURES}; then
+			ewarn "${notestmsg}"
+	else
+		pushd "${BUILD_DIR}"/lib >/dev/null || die
+		# module import will fail with any other directory structure
+		cp -rv "${S}"/tests ./ || die
+		pytest -vv || die "Tests fail with ${EPYTHON}"
+		popd >/dev/null || die
+	fi
+}
-- 
cgit v1.2.3-65-gdbad