From 13f34d68fc08b73e70addd04b3c4db254138d8fe Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Mon, 28 Aug 2023 18:20:38 +0200
Subject: dev-python/oslo-log: Bump to 5.3.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/oslo-log/Manifest              |  1 +
 dev-python/oslo-log/oslo-log-5.3.0.ebuild | 69 +++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)
 create mode 100644 dev-python/oslo-log/oslo-log-5.3.0.ebuild

(limited to 'dev-python/oslo-log')

diff --git a/dev-python/oslo-log/Manifest b/dev-python/oslo-log/Manifest
index a6b8b71e3107..bbced50794d8 100644
--- a/dev-python/oslo-log/Manifest
+++ b/dev-python/oslo-log/Manifest
@@ -1 +1,2 @@
 DIST oslo.log-5.2.0.tar.gz 93528 BLAKE2B d52ee82e9e2d422649e9bc0baab77c8f72e3640cfba44d326daa759e746d8f83aa04fd5f3f6b7b9e2ffcced910706b85407f3f3f4f83755b48f7883d2150ac61 SHA512 171606a0e93f2a354c8b4369e6674d25b4f2e25a5c91ca3760beb753d7cc9b0d64754ec4ccb10785db3e5b40655be5f0c5f17bf5a3095af6077771a9cd7c2f4b
+DIST oslo.log-5.3.0.tar.gz 96999 BLAKE2B de8e6173bbea2bf30eb0da056144b25f7da74cfcaf2f6ce70619da86ec3babeda5c5c4784c055950bbfef724a807db6e25cb9792eecdf242ae2bcca00e3810fb SHA512 7db802c9c753562351c34feb63ebdff1306911ef392e4742fb08cfda08d8b09a81cb0e3ff85162ecd54a164a9c38a3a6f5a4d7cfc26bbd9ee84fefd172ca2fbd
diff --git a/dev-python/oslo-log/oslo-log-5.3.0.ebuild b/dev-python/oslo-log/oslo-log-5.3.0.ebuild
new file mode 100644
index 000000000000..9166896935aa
--- /dev/null
+++ b/dev-python/oslo-log/oslo-log-5.3.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="OpenStack logging config library, configuration for all openstack projects"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.log/
+	https://github.com/openstack/oslo.log/
+	https://pypi.org/project/oslo.log/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pbr-3.1.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.20.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.25.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.19.0[${PYTHON_USEDEP}]
+	>=dev-python/pyinotify-0.9.6[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.7.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-3.1.1[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/testtools-2.3.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc/source \
+	dev-python/openstackdocstheme \
+	dev-python/oslo-config
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local EPYTEST_IGNORE=(
+		# requires eventlet
+		oslo_log/tests/unit/test_pipe_mutex.py
+	)
+	local EPYTEST_DESELECT=(
+		# messed up with pytest
+		oslo_log/tests/unit/fixture/test_logging_error.py::TestLoggingFixture::test_logging_handle_error
+	)
+
+	case ${EPYTHON} in
+		python3.11)
+			# upstream is... *sigh*
+			EPYTEST_DESELECT+=(
+				oslo_log/tests/unit/test_log.py::LogConfigTestCase::test_log_config_append_invalid
+			)
+	esac
+
+	epytest
+}
-- 
cgit v1.2.3-65-gdbad