From 4f0988043e55b524429f0246b727bef12b7de489 Mon Sep 17 00:00:00 2001
From: Alexander Barker <alex@1stleg.com>
Date: Sun, 12 Apr 2020 11:58:14 -0700
Subject: dev-libs/libratbag: Bump to version 0.15

Bug: https://bugs.gentoo.org/682372
Closes: https://bugs.gentoo.org/682372
Signed-off-by: Alex Barker <alex@1stleg.com>
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 dev-libs/libratbag/Manifest              |  1 +
 dev-libs/libratbag/libratbag-0.15.ebuild | 79 ++++++++++++++++++++++++++++++++
 dev-libs/libratbag/metadata.xml          |  9 +++-
 3 files changed, 88 insertions(+), 1 deletion(-)
 create mode 100644 dev-libs/libratbag/libratbag-0.15.ebuild

(limited to 'dev-libs/libratbag')

diff --git a/dev-libs/libratbag/Manifest b/dev-libs/libratbag/Manifest
index f5299d58a683..79be00306870 100644
--- a/dev-libs/libratbag/Manifest
+++ b/dev-libs/libratbag/Manifest
@@ -1 +1,2 @@
+DIST libratbag-0.15.tar.gz 249492 BLAKE2B 0f5b35800cb9f82cb892dacd5e3b041843cf5513507ee4882ec5b3f8c8aec8a24594736f2eb1c8e373a0ee38ace1e6328cbd4816d6e5b2cd1f2154ebd803a5fa SHA512 add47a6b3d771de77c6307e128a549f5295e216059b5a2375aa6b2b6bbebcf9a93d7bf148181b3f39f855976e9b6f57072dd9198d07828bebe85409f4ad994aa
 DIST libratbag-0.9.tar.gz 238225 BLAKE2B 74efbed2840103018195a73c11760a2022e42db5e81ba2e9d63a21bc5eb4c1dfed107382b657d2dc208101dfb53eb1926aaccc116ae66e3bf83e1218239dc1a2 SHA512 36215f534f9429c3b182f5502a2bbe16905492a634e327a845d65b638d7dd5ebb5c4eb1700a5196d6b5caac68e500603ced60c3c83f6d0c8e3c776e0161f657b
diff --git a/dev-libs/libratbag/libratbag-0.15.ebuild b/dev-libs/libratbag/libratbag-0.15.ebuild
new file mode 100644
index 000000000000..599db86cfd67
--- /dev/null
+++ b/dev-libs/libratbag/libratbag-0.15.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit meson python-single-r1 udev
+
+DESCRIPTION="Library to configure gaming mice"
+HOMEPAGE="https://github.com/libratbag/libratbag"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc elogind systemd test"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	^^ ( elogind systemd )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-lang/swig
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? (
+		dev-libs/gobject-introspection
+		dev-util/valgrind
+		$(python_gen_cond_dep '
+			dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+			dev-python/python-evdev[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection
+	dev-libs/libevdev
+	virtual/libudev
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+		dev-python/python-evdev[${PYTHON_MULTI_USEDEP}]
+	')
+	elogind? ( sys-auth/elogind )
+	systemd? ( sys-apps/systemd )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	if use elogind ; then
+		# Fix systemd includes for elogind
+		sed -i -e 's@include <systemd@include <elogind@' \
+			ratbagd/ratbag*.c || die
+	fi
+}
+
+src_configure() {
+	python_setup
+
+	local emesonargs=(
+		$(meson_use systemd)
+		-Dlogind-provider=$(usex elogind elogind systemd)
+		$(meson_use doc documentation)
+		$(meson_use test tests)
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}"/usr/bin/
+}
diff --git a/dev-libs/libratbag/metadata.xml b/dev-libs/libratbag/metadata.xml
index 7899bfbe42b7..2ae9cbec3558 100644
--- a/dev-libs/libratbag/metadata.xml
+++ b/dev-libs/libratbag/metadata.xml
@@ -1,7 +1,14 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-  <!-- maintainer-needed -->
+  <maintainer type="person">
+    <email>alex@1stleg.com</email>
+    <name>Alex Barker</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>proxy-maint@gentoo.org</email>
+    <name>Proxy Maintainers</name>
+  </maintainer>
   <upstream>
     <remote-id type="github">libratbag/libratbag</remote-id>
   </upstream>
-- 
cgit v1.2.3-65-gdbad