From 70af2a4224a603c3e1aa3e21854ea7a4aea6bdcb Mon Sep 17 00:00:00 2001
From: Patrice Clement <monsieurp@gentoo.org>
Date: Fri, 12 May 2017 14:44:26 +0200
Subject: app-editors/ne: EAPI 6 bump.

Package-Manager: Portage-2.3.5, Repoman-2.3.1
---
 app-editors/ne/ne-3.0.1-r1.ebuild | 53 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 app-editors/ne/ne-3.0.1-r1.ebuild

(limited to 'app-editors/ne')

diff --git a/app-editors/ne/ne-3.0.1-r1.ebuild b/app-editors/ne/ne-3.0.1-r1.ebuild
new file mode 100644
index 000000000000..9d68adc0f1a0
--- /dev/null
+++ b/app-editors/ne/ne-3.0.1-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="the nice editor, easy to use for the beginner and powerful for the wizard"
+HOMEPAGE="http://ne.di.unimi.it/"
+SRC_URI="${HOMEPAGE}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="tinfo"
+
+DEPEND="sys-libs/ncurses:0=[tinfo?]"
+
+RDEPEND="
+	${DEPEND}
+	dev-lang/perl
+"
+
+HTML_DOCS=( doc/html/. )
+
+src_prepare() {
+	default
+	sed -i -e 's/-O3//' src/makefile || die
+}
+
+src_configure() {
+	local sedflags="s|-lcurses|-lncurses|g"
+	use tinfo && sedflags="s|-lcurses|-ltinfo|g"
+	sed -i -e "${sedflags}" src/makefile || die
+}
+
+src_compile() {
+	append-cflags -std=c11
+	emake -C src CC="$(tc-getCC)" \
+		NE_GLOBAL_DIR="/usr/share/${PN}" \
+		OPTS="${CFLAGS}" \
+		"${PN}"
+}
+
+src_install() {
+	dobin "src/${PN}"
+
+	insinto "/usr/share/${PN}/syntax"
+	doins syntax/*.jsf
+
+	doman "doc/${PN}.1"
+	dodoc CHANGES README.md NEWS doc/*.{txt,pdf,texinfo} doc/default.*
+}
-- 
cgit v1.2.3-65-gdbad