From b890aa10fa46b6e5c34631de1cc1f2c0a5533593 Mon Sep 17 00:00:00 2001
From: Petr Vaněk <arkamar@gentoo.org>
Date: Thu, 8 Aug 2024 11:21:25 +0200
Subject: app-backup/borgbackup: add 1.4.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/935815
Signed-off-by: Petr Vaněk <arkamar@gentoo.org>
---
 app-backup/borgbackup/Manifest                |  1 +
 app-backup/borgbackup/borgbackup-1.4.0.ebuild | 69 +++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)
 create mode 100644 app-backup/borgbackup/borgbackup-1.4.0.ebuild

(limited to 'app-backup')

diff --git a/app-backup/borgbackup/Manifest b/app-backup/borgbackup/Manifest
index cec374466abc..9938cd533a7a 100644
--- a/app-backup/borgbackup/Manifest
+++ b/app-backup/borgbackup/Manifest
@@ -1 +1,2 @@
 DIST borgbackup-1.2.8.tar.gz 4369117 BLAKE2B f230274189716e6ecb8f73d10caa13e683e63c9d9f50c5b6235fc666a0f64f3048421e76e5b57626144c37d37d28c4371b368f780f5e32055f62d5ff10954c19 SHA512 9a62e5eec894ebffe928a08c9a0cceebde084f16524d363a3c3be01d908a7eceaea8fa11eac422acc0fdb2534d79d1ee5ec5d9167e1086f334af6a28887616d5
+DIST borgbackup-1.4.0.tar.gz 3798511 BLAKE2B 06d4d67e211a3ab1bc6d7155cbce8205fb7408a1149e44c77b500af02c25e62a569e3eaf50c11916a2ff9adea47c5791febfb7d0c657d0b195e5c5bbbd33a7d7 SHA512 f5866ece2d153d1e43127a04fd288a09403a9ea2ae4c981cb9ff855bd303b53c133c006f0b1a77541edc4f64940431e9c4d49ec45a3646784a29fe3b8828237a
diff --git a/app-backup/borgbackup/borgbackup-1.4.0.ebuild b/app-backup/borgbackup/borgbackup-1.4.0.ebuild
new file mode 100644
index 000000000000..8b663ddc3aab
--- /dev/null
+++ b/app-backup/borgbackup/borgbackup-1.4.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit bash-completion-r1 distutils-r1 pypi
+
+DESCRIPTION="Deduplicating backup program with compression and authenticated encryption"
+HOMEPAGE="https://borgbackup.readthedocs.io/"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	app-arch/lz4
+	app-arch/zstd
+	dev-libs/openssl:0=
+	>=dev-libs/xxhash-0.8.1
+	virtual/acl
+"
+# borgbackup is *very* picky about which msgpack it work with,
+# check setup.py on bumps.
+RDEPEND="
+	${DEPEND}
+	<=dev-python/msgpack-1.1.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pyfuse3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)
+"
+
+# some tests randomly fail with xdist, bug #936524
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Needs pytest-benchmark fixture
+		benchmark.py::test_
+	)
+
+	# This disables fuse releated tests
+	local -x BORG_FUSE_IMPL="none"
+	epytest --pyargs borg.testsuite
+}
+
+src_install() {
+	distutils-r1_src_install
+	doman docs/man/*
+
+	dobashcomp scripts/shell_completions/bash/borg
+
+	insinto /usr/share/zsh/site-functions
+	doins scripts/shell_completions/zsh/_borg
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins scripts/shell_completions/fish/borg.fish
+}
-- 
cgit v1.2.3-65-gdbad