From b7ee409fcc24a83eb6096c6d38176b41338780d0 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Fri, 16 Feb 2024 23:50:36 +0000
Subject: sys-apps/bfs: add 3.1.1

Signed-off-by: Sam James <sam@gentoo.org>
---
 sys-apps/bfs/Manifest         |  1 +
 sys-apps/bfs/bfs-3.1.1.ebuild | 46 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 47 insertions(+)
 create mode 100644 sys-apps/bfs/bfs-3.1.1.ebuild

diff --git a/sys-apps/bfs/Manifest b/sys-apps/bfs/Manifest
index e73be02918bd..1a54b8d1e4cf 100644
--- a/sys-apps/bfs/Manifest
+++ b/sys-apps/bfs/Manifest
@@ -1 +1,2 @@
+DIST bfs-3.1.1.tar.gz 234742 BLAKE2B efb0cd9ceb6105697983bb91d1ce7e149afbb372e6df03d76d63e0922fcd0542675a55cc18cbbb44134d4ae07dc72beb0d64ce848919d5b5f152c378af2b7d4b SHA512 98696cead293281d3b7f29e01abaa6c8de83a8ea32353fcb5ec11daad47692e67b40e4f402cd5012782203101133e8ba42dd9e3c678a2b1066f65dc0145ec1b8
 DIST bfs-3.1.tar.gz 234153 BLAKE2B a5b501016b1513dc9a3964ed4167db37c9a810e49a565059275919d234becf4f66300bdade48f3cde69a952ed0a6c68ee7f4adaf0e500e433f8cf75cc76f3db2 SHA512 d2be9d931d2a53fb292431551cc881103584a75d444f91d4e7d92dffe781aa9cdeda7281ab0c7598e8bfdd944b1392e345eff4bd2e60ea5ae65491f8860d862d
diff --git a/sys-apps/bfs/bfs-3.1.1.ebuild b/sys-apps/bfs/bfs-3.1.1.ebuild
new file mode 100644
index 000000000000..06c9ba6cc7f1
--- /dev/null
+++ b/sys-apps/bfs/bfs-3.1.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="Breadth-first version of the UNIX find command"
+HOMEPAGE="https://tavianator.com/projects/bfs.html"
+SRC_URI="https://github.com/tavianator/bfs/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="0BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64"
+IUSE="acl caps debug io-uring unicode xattr"
+
+DEPEND="
+	acl? ( virtual/acl )
+	caps? ( sys-libs/libcap )
+	io-uring? ( sys-libs/liburing:= )
+	unicode? ( dev-libs/oniguruma:= )
+	xattr? ( sys-apps/attr )
+"
+RDEPEND="${DEPEND}"
+
+bfsmake() {
+	emake \
+		USE_ACL=$(usev acl '1') \
+		USE_ATTR=$(usev xattr '1') \
+		USE_LIBCAP=$(usev caps '1') \
+		USE_LIBURING=$(usev io-uring '1') \
+		USE_ONIGURUMA=$(usev unicode '1') \
+		"$@"
+}
+
+src_compile() {
+	tc-export CC
+	use debug || append-cppflags -DNDEBUG
+
+	bfsmake
+}
+
+src_test() {
+	# -n check gets confused so need manual src_test definition?
+	bfsmake check
+}
-- 
cgit v1.2.3-65-gdbad