1 files changed, 46 insertions, 0 deletions
diff --git a/sci-electronics/sigrok-cli/sigrok-cli-0.5.0.ebuild b/sci-electronics/sigrok-cli/sigrok-cli-0.5.0.ebuild
new file mode 100644
index 000000000000..3c7a347167ed
--- /dev/null
+++ b/sci-electronics/sigrok-cli/sigrok-cli-0.5.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+PYTHON_COMPAT=( python3_{3,4} )
+inherit eutils python-single-r1
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="git://sigrok.org/${PN}"
+	inherit git-2 autotools
+else
+	SRC_URI="http://sigrok.org/download/source/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Command-line client for the sigrok logic analyzer software"
+HOMEPAGE="http://sigrok.org/wiki/Sigrok-cli"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+decode"
+REQUIRED_USE="decode? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND=">=dev-libs/glib-2.28.0
+	>=sci-libs/libsigrok-0.3.0
+	decode? (
+		>=sci-libs/libsigrokdecode-0.3.0
+		${PYTHON_DEPS}
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	[[ ${PV} == "9999" ]] && eautoreconf
+
+	# This is fixed after the 0.5.0 release.
+	sed -i \
+		-e '/WITH_SRD=$enableval/s:=$enableval:=$withval:' \
+		configure || die
+}
+
+src_configure() {
+	econf $(use_with decode libsigrokdecode)
+}