1 files changed, 50 insertions, 0 deletions
diff --git a/net-wireless/chirp/chirp-20200807.ebuild b/net-wireless/chirp/chirp-20200807.ebuild
new file mode 100644
index 000000000000..77faba828a0c
--- /dev/null
+++ b/net-wireless/chirp/chirp-20200807.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 )
+
+if [[ ${PV} == "99999999" ]] ; then
+	SCM=mercurial
+	EHG_REPO_URI="http://d-rats.com/hg/chirp.hg"
+else
+	RESTRICT="test"
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://trac.${PN}.danplanet.com/${PN}_daily/daily-${PV}/${PN}-daily-${PV}.tar.gz"
+	S="${WORKDIR}/${PN}-daily-${PV}"
+fi
+
+inherit distutils-r1 xdg-utils ${SCM}
+
+DESCRIPTION="Free open-source tool for programming your amateur radio"
+HOMEPAGE="https://chirp.danplanet.com"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="radioreference"
+
+DEPEND="${PYTHON_DEPS}
+	dev-python/pyserial[${PYTHON_USEDEP}]
+	dev-libs/libxml2[python]"
+RDEPEND="${DEPEND}
+	dev-python/pygtk[${PYTHON_USEDEP}]
+	radioreference? ( dev-python/suds[${PYTHON_USEDEP}] )"
+
+src_prepare() {
+	sed -i -e "/share\/doc\/chirp/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	pushd tests > /dev/null
+	"${PYTHON}" run_tests || die
+	popd > /dev/null
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}