1 files changed, 55 insertions, 0 deletions
diff --git a/gnome-extra/gnome-shell-extension-bing-wallpaper/gnome-shell-extension-bing-wallpaper-44.ebuild b/gnome-extra/gnome-shell-extension-bing-wallpaper/gnome-shell-extension-bing-wallpaper-44.ebuild
new file mode 100644
index 000000000000..c449d1c4f90f
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-bing-wallpaper/gnome-shell-extension-bing-wallpaper-44.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome2-utils
+
+DESCRIPTION="Changes your wallpaper daily to the bing.com background image"
+HOMEPAGE="https://github.com/neffo/bing-wallpaper-gnome-extension"
+SRC_URI="https://github.com/neffo/bing-wallpaper-gnome-extension/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-libs/glib:2
+	app-eselect/eselect-gnome-shell-extensions
+	>=gnome-base/gnome-shell-3.36
+"
+DEPEND=""
+BDEPEND=""
+
+S="${WORKDIR}/bing-wallpaper-gnome-extension-${PV}"
+extension_uuid="BingWallpaper@ineffable-gmail.com"
+
+PATCHES=(
+	# https://github.com/neffo/bing-wallpaper-gnome-extension/issues/113
+	"${FILESDIR}/${PN}-44-unlock-screen.patch"
+)
+
+src_install() {
+	einstalldocs
+	rm -f README.md LICENSE || die
+	insinto /usr/share/glib-2.0/schemas
+	doins schemas/*.xml
+	rm -rf schemas
+	insinto /usr/share/gnome-shell/extensions/"${extension_uuid}"
+	doins -r *
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}