1 files changed, 43 insertions, 0 deletions
diff --git a/dev-libs/skalibs/skalibs-2.13.1.1.ebuild b/dev-libs/skalibs/skalibs-2.13.1.1.ebuild
new file mode 100644
index 000000000000..746086486c1a
--- /dev/null
+++ b/dev-libs/skalibs/skalibs-2.13.1.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="General-purpose libraries from skarnet.org"
+HOMEPAGE="https://www.skarnet.org/software/skalibs/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+HTML_DOCS=( doc/. )
+
+src_prepare() {
+	default
+
+	# Avoid QA warning for LDFLAGS addition
+	sed -i -e 's/.*-Wl,--hash-style=both$/:/' configure || die
+
+	sed -i -e '/AR := /d' -e '/RANLIB := /d' Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC RANLIB
+
+	local myconf=(
+		--datadir=/etc
+		--dynlibdir="/$(get_libdir)"
+		--libdir="/usr/$(get_libdir)/${PN}"
+		--sysdepdir="/usr/$(get_libdir)/${PN}"
+
+		--disable-static
+		--enable-clock
+		--enable-ipv6
+		--enable-shared
+	)
+
+	econf "${myconf[@]}"
+}