1 files changed, 59 insertions, 0 deletions
diff --git a/app-emulation/docker-runc/docker-runc-1.0.0_rc4_p20170926.ebuild b/app-emulation/docker-runc/docker-runc-1.0.0_rc4_p20170926.ebuild
new file mode 100644
index 000000000000..e87d7dd2df94
--- /dev/null
+++ b/app-emulation/docker-runc/docker-runc-1.0.0_rc4_p20170926.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+EGO_PN="github.com/opencontainers/${PN/docker-}"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit golang-vcs
+else
+	MY_PV="${PV/_/-}"
+	EGIT_COMMIT="0351df1c5a66838d0c392b4ac4cf9450de844e2d"
+	RUNC_COMMIT="0351df1" # Change this when you update the ebuild
+	SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc64"
+	inherit golang-vcs-snapshot
+fi
+
+DESCRIPTION="runc container cli tools (docker fork)"
+HOMEPAGE="http://runc.io"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+ambient apparmor hardened +seccomp"
+
+RDEPEND="
+	apparmor? ( sys-libs/libapparmor )
+	seccomp? ( sys-libs/libseccomp )
+	!app-emulation/runc
+"
+
+S=${WORKDIR}/${P}/src/${EGO_PN}
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	sed -i -e "s/git rev-parse.*\$/echo gentoo)/" -e "/COMMIT :=/d" -e "/COMMIT_NO :=/d" Makefile || die
+}
+
+src_compile() {
+	# Taken from app-emulation/docker-1.7.0-r1
+	export CGO_CFLAGS="-I${ROOT}/usr/include"
+	export CGO_LDFLAGS="$(usex hardened '-fno-PIC ' '')
+		-L${ROOT}/usr/$(get_libdir)"
+
+	# build up optional flags
+	local options=(
+		$(usex ambient 'ambient' '')
+		$(usex apparmor 'apparmor' '')
+		$(usex seccomp 'seccomp' '')
+	)
+
+	GOPATH="${WORKDIR}/${P}" emake BUILDTAGS="${options[*]}" \
+		COMMIT="${RUNC_COMMIT}"
+}
+
+src_install() {
+	dobin runc
+}