x11-themes/tela-icon-theme: Add 20230203

Signed-off-by: Steffen Winter <steffen.winter@proton.me>
Closes: https://github.com/gentoo/gentoo/pull/30591
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

2 files changed, 71 insertions, 1 deletions

diff --git a/x11-themes/tela-icon-theme/Manifest b/x11-themes/tela-icon-theme/Manifest
index bd10d9e3bba9..af1f0aaa500f 100644
--- a/x11-themes/tela-icon-theme/Manifest
+++ b/x11-themes/tela-icon-theme/Manifest
@@ -1 +1 @@
-DIST tela-icon-theme-20220828.tar.gz 3707567 BLAKE2B 61a72b96df08cb5f3ef80b7aea5ca05e9b142607672f7213494c6f9fd0f458eeb87bd80842e14b7ed260f533088711f433357179c7c53d5beeeb76bafe2817d5 SHA512 6f0d26678ead12043bfc8943e2d40a507c2cfa8136a1556d53444efa5b1f6903307aead9255a38b3411980bd5353c3497bf224c1ed66a620d229b6a9a9079f83
+DIST tela-icon-theme-20230203.tar.gz 3774147 BLAKE2B c0b04ec934ed68a7d6267be030af861cf9c2c24e8367baebbc56b788f4dbec56dda2679190f33c739a04ed9ca3088138a1f89624e9beebf715149fbef2478576 SHA512 28ad9e67394ffa65bd1fe6052e38dd324487be621670bff933f3bb2aeee9134e656f1f8faebb060d5d765b808e008d5fede3d62a51b9ddca1e8047c927f3bdd1
diff --git a/x11-themes/tela-icon-theme/tela-icon-theme-20230203.ebuild b/x11-themes/tela-icon-theme/tela-icon-theme-20230203.ebuild
new file mode 100644
index 000000000000..c6ef1f2ee896
--- /dev/null
+++ b/x11-themes/tela-icon-theme/tela-icon-theme-20230203.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit edo
+
+# eg. 20211225 -> 2021-12-25
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
+MY_PN="${PN^}"
+
+# standard comes first
+MY_COLOR_VARIANTS=( standard black blue brown green grey orange pink purple red yellow manjaro ubuntu dracula nord )
+
+inherit xdg
+
+DESCRIPTION="A flat colorful Design icon theme"
+HOMEPAGE="https://github.com/vinceliuice/Tela-icon-theme"
+
+if [[ ${PV} == 99999999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/vinceliuice/${MY_PN}.git"
+else
+	SRC_URI="https://github.com/vinceliuice/${MY_PN}/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64"
+	S="${WORKDIR}/${MY_PN}-${MY_PV}"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+${MY_COLOR_VARIANTS[*]} +hardlink kde" # this is why standard comes first
+
+REQUIRED_USE="|| ( ${MY_COLOR_VARIANTS[*]} )"
+
+# not needed and slows us down, package installs 120 000 small files
+RESTRICT="binchecks strip test"
+
+# technically we can use app-arch/hardlink too, but it's deprecated
+BDEPEND="
+	app-shells/bash
+	sys-apps/util-linux[hardlink(-)?]
+"
+
+src_prepare() {
+	default
+	# we use eclass for that
+	sed -i '/gtk-update-icon-cache/d' install.sh || die
+}
+
+src_install() {
+	local v variants=(
+		$(for v in ${MY_COLOR_VARIANTS[@]}; do
+			usev ${v}
+		done)
+		$(usev kde '-c')
+	)
+
+	dodir /usr/share/icons
+	./install.sh -d "${ED}/usr/share/icons" "${variants[@]}" || die
+	if use hardlink; then
+		einfo "Linking duplicate icons... (may take a long time)"
+		hardlink -pot "${ED}/usr/share/icons" || die "hardlink failed"
+	fi
+
+	# installs broken symlink (by design, but we remove it due to QA warnings)
+	# https://bugs.gentoo.org/830467
+	edob find "${ED}" -xtype l -print -delete
+
+	einstalldocs
+}