www-client/opera-beta: automated bump (90.0.4480.37)

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 159 insertions, 0 deletions

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index 2842a9f7f634..937756179cd3 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,5 +1,6 @@
 DIST opera-beta_89.0.4447.37_amd64.deb 86976092 BLAKE2B e6a094370fe58946b6217588ab45d135938d1540db5d51caca89c6d7dc40c5f13f19d453ad2fe57a731ec799e2996b10bc62c9efd4a99b034643288447e58e43 SHA512 d4c0622919043bcac442063323e8f46c91860b785e4d36007a88386bcbfa36bd87df8f4467a59014df1f04b94a8f5bc737b42194a132fdea5c2e6f4ca5b03f96
 DIST opera-beta_90.0.4480.25_amd64.deb 87712392 BLAKE2B 939b94c36a380913f944378f10026f726f154e5a0f359b6d233ea4cca51c1ee7cd86008c6599add44bc6e9f258aa8c2196cf942bb7a86da25ab4f6c5c4c9a7dc SHA512 40f1fbf146da283f31924e31edfd6ffbd70596f273191a7b9ae68a438db50e02b3fdbe9d809e875ad0148c04983778a1c06077af696ff7803796b76558e0fb90
 DIST opera-beta_90.0.4480.30_amd64.deb 87759060 BLAKE2B d3f07fbf6e4b53ae70da344586f963f8259cc081fca7bc9642f424b76b5da97e7e68f59ce685ed68d962a648982e34e1f829f3f9a91287b003802c81c1c412dc SHA512 3e9a5156825b3ce39f85df5f9ab06df9f5836fc216ba7890b87b4db532784f1529797763296fac9ba0f8f28d4cbe904857f967dc074c4f5ef5e4e6b375a2e879
+DIST opera-beta_90.0.4480.37_amd64.deb 87760936 BLAKE2B 893e91922235c24601f9e071f688179baefc7d646aa39714edfe33b44a3d5d44b9095ea1cbf886c9ff54cb692d78f9faa61d7f1ae47be1e938415d6696d3e6a8 SHA512 d3a956881dcaa99e14befa95b1e9c2a07fc6ec3c0937ff2d74b6e1523e6566c14c5e3c308478f58307e91bb343c11f40ab4c0f64b45a93e9f973e270d47e0677
 DIST opera-ffmpeg-codecs-102.0.5005.61.tar.xz 1429920 BLAKE2B a4cb07805650c3cd7f7e1127e475775c95d74b8cd17af5ad736a6d4f256176586b1608c2a617961cf2f3f7980879bc8f1a84cd9faa4838eafbc7b1b4e2edfe1a SHA512 af20383a0b77da89bf2ef52b412d9cce0a1f12bcfe2612ebd5110f1e8008cfff874da36e00b980609ac29346c545f2326bbe5f1b42473530f2886d67a00f52ca
 DIST opera-ffmpeg-codecs-104.0.5083.0.tar.xz 1431840 BLAKE2B 172ba55d6f390eaea644803ddae8c3cee4ee2d585de873db438d43b9e7f6d07f5b0e9b659f06c126f65148148d889948cc3287ee21da00eec08f2e665be47dbc SHA512 9ca7fe8a244b634d65a28602f9e1173694faaab6de95cd0a44aeedc29dffb75b14adf842c69d5ba5631fb40e51f021fce190dc8307148d8e9218230b7cde29b8
diff --git a/www-client/opera-beta/opera-beta-90.0.4480.37.ebuild b/www-client/opera-beta/opera-beta-90.0.4480.37.ebuild
new file mode 100644
index 000000000000..bf2f16f337f7
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-90.0.4480.37.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="104.0.5083.0"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}