sys-kernel/gentoo-kernel-bin: bump to 5.4.111 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 27614ef2757b..7f7cf63d018d 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -93,6 +93,7 @@ DIST gentoo-kernel-5.4.110-1.amd64.xpak 61394099 BLAKE2B 5907a7f6ffa336e6044c47b
 DIST gentoo-kernel-5.4.110-1.arm64.xpak 56429255 BLAKE2B 714380f1f515bc30796d7b19c21b5565664c0ec1db016f10371d2d4e03ebd3d6fdef0d6891b694bda5032f99e98805960e19012723de1168f9cf41b44022bee2 SHA512 4ab7b907d9dec2147390a13052b7579fcbf9473cebff5d3bca25934de8b12c04935f9d2a62a3beae136e3897dc7702c7dd00aba6d60cd662d940b07a68dcd3af
 DIST gentoo-kernel-5.4.110-1.x86.xpak 53179555 BLAKE2B 39ed8da5d56906c750502a33062aecd67d0561f69df1efbbefe55ea960167baad1ed70a8b9c27a0158fad8fc7378f8af1bc86784c3b2fdbe5661fda3cee0a853 SHA512 f0aa83b79be333191a7e161533604e9fde45e62cf32df535059883b0daf101e54ecdaf93ee1b278228ce8ccd9228b750d05206223ecd922383688158c847bc2d
 DIST gentoo-kernel-5.4.111-1.amd64.xpak 61359873 BLAKE2B 4144dc53feda9d1169edfa36d8e4993b92bb363020cec09a34a7ea03df0e802a332d7d3fb58d3a74ed5c668c81fcd0a3a0c1b8add2658126dd208f88ff7b513c SHA512 a9bbe6e08cecb1da40359d3a69e2cb20e751773dd4702c1d6406fa7cfc5fd09c966931984cc1c88c12776c7e979c5293a6cb85fa975d96f3bfcd81c704a7da3b
+DIST gentoo-kernel-5.4.111-1.arm64.xpak 56472651 BLAKE2B 07ff38c5424d59125adfc12d3f300c6bc4431fca371fbf9a743b0f3f9ce964713fa549163ac89180029e3cf3989729a7011215cc1c3b18f6291d0e4ef61c942c SHA512 9fed19fb0c3be2ad3ca8c55ff0b8b275def071d93b41b7d9b52f8b131faaec2f4b6a6165d799082bd6cc5dee7226ada3e6a00933b0f172b506bb99a0be603272
 DIST gentoo-kernel-5.4.111-1.x86.xpak 53176206 BLAKE2B 0c0975b11d7c10d53544d1323f24c576a85dbdb86ad923262c2fe1c5785385127d5de1c6752d2b8926a372f96ccbaf10eb562970db73ebd25281f00016e40cb1 SHA512 e32b887d059b0a6ecc83929a1a0e406620dce2db21cd672386f3b5a81af02449a08d890a4321ce4f7eb9afa58023170b076ddae8d8b71b240edecad0721620d0
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.11.tar.xz 117619104 BLAKE2B 81300c27bd5476387a83123aaeb4163c73eb61e9245806c23660cb5e6a4fa88ffc9def027031335fa0270fc4080506cd415990014364e3a98b9d2e8c58a29524 SHA512 a567ec133018bb5ec00c60281479b466c26e02137a93a9c690e83997947df02b6fd94e76e8df748f6d70ceb58a19bacc3b1467de10b7a1fad2763db32b3f1330
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.111-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.111-r1.ebuild
new file mode 100644
index 000000000000..b63276300c50
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.111-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}