net-irc/limnoria: Bump to 20171025

Bug: https://bugs.gentoo.org/636992
Package-Manager: Portage-2.3.13, Repoman-2.3.4

2 files changed, 91 insertions, 0 deletions

diff --git a/net-irc/limnoria/Manifest b/net-irc/limnoria/Manifest
index eebee71e57e0..f5538b20e4b2 100644
--- a/net-irc/limnoria/Manifest
+++ b/net-irc/limnoria/Manifest
@@ -1,2 +1,3 @@
 DIST limnoria-20150523.tar.gz 937583 SHA256 16d7e9ccfddfb67eca616997be938b268347be7b17ccc43d38aea6b48bb3cd0e SHA512 d94ea8fe64a648605e8e45317f3283fac837e8bfe1465407fa7522ea5e2259c64a0ea3aa4585313b5c21def735fa7b0e62d7774fabfc2647683efc2f4c38d599 WHIRLPOOL 40baeebf15051a5bc36a39645f984ba9aa4710e8da08cf53bb69e330b3ba6a62c40317919ba5a7ea0e3841187e89087054f1072862d512dff9443e812d4728b8
 DIST limnoria-20150829.tar.gz 939733 SHA256 b86ca1cb24b6f54c9e892a978c1afad1df17cb9308883764f6cc7381e2d124dc SHA512 51c941adf596716a610f6233a606958eae39fb90ad2ab02fcde670596c174b99196da7d29d31c438db0eeb79bd2d8c1067fdf21f0e6e42ba25a80cd5249b89a2 WHIRLPOOL 118f532c2ec4c9b75a7194bc2ea65e9aa707601276fbb3abf7066f5e96d297a7454fb0d477aa9e595d9dadb4750f00a549e78f5408a15a3c264526a8b83dd507
+DIST limnoria-20171025.tar.gz 957078 SHA256 9cd4ab29d510fe7e84ed54bd8ba273acd2d2de2de5b133e679db54505f6c36b2 SHA512 513a04b860e1fc1788de41238c858fa487899988111d9f5bfaa4acde6506dbd4bdf4dd26e48d268f6ca2f1b301b3e8d9aad8a2733013c09db69ffb4f925a7c12 WHIRLPOOL 9f80cfb7ba16de146c4378d457ce998fd04d16e1324f88ba6ab1563c2165db11c20d1c5bf8c60c39388f5e1390623cc640830d4436abf903d291c02618c315c3
diff --git a/net-irc/limnoria/limnoria-20171025.ebuild b/net-irc/limnoria/limnoria-20171025.ebuild
new file mode 100644
index 000000000000..0280102ac95c
--- /dev/null
+++ b/net-irc/limnoria/limnoria-20171025.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
+MY_PN="Limnoria"
+MY_P="${MY_PN}-${MY_PV}"
+
+if [[ ${PV} == "99999999" ]]; then
+	EGIT_REPO_URI="https://github.com/ProgVal/${MY_PN}.git"
+	EGIT_BRANCH="testing"
+	inherit git-r3
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/ProgVal/${MY_PN}/archive/master-${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${MY_PN}-master-${MY_PV}"
+fi
+
+DESCRIPTION="Python based extensible IRC infobot and channel bot"
+HOMEPAGE="https://supybot.aperio.fr/"
+LICENSE="BSD"
+SLOT="0"
+IUSE="crypt ssl test"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/ecdsa[${PYTHON_USEDEP}]
+	dev-python/feedparser[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	crypt? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
+	ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
+	!net-irc/supybot
+	!net-irc/supybot-plugins
+	"
+DEPEND="${RDEPEND}
+	test? ( $(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7) )"
+
+src_unpack() {
+	if [[ ${PV} == "99999999" ]]; then
+		git-r3_src_unpack
+	else
+		unpack ${P}.tar.gz
+	fi
+}
+
+python_prepare(){
+	distutils-r1_python_prepare
+	if python_is_python3; then
+		einfo "Removing the RSS plugin because of clashes between libxml2's Python3"
+		einfo "bindings and feedparser."
+		rm -rf "plugins/RSS" || die
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	doman man/*
+}
+
+python_test() {
+	pushd "${T}" > /dev/null
+	PLUGINS_DIR="${BUILD_DIR}/lib/supybot/plugins"
+	# recommended by upstream, unknown random failure
+	EXCLUDE_PLUGINS=( --exclude="${PLUGINS_DIR}/Scheduler" )
+	# recommended by upstream, unknown random failure
+	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Filter" )
+	# intermittent failure due to issues loading libsandbox.so from LD_PRELOAD
+	# runs successfully when running the tests on the installed system
+	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Unix" )
+	"${PYTHON}" "${BUILD_DIR}"/scripts/supybot-test "${BUILD_DIR}/../test" \
+		--plugins-dir="${PLUGINS_DIR}" --no-network \
+		--disable-multiprocessing "${EXCLUDE_PLUGINS[@]}" \
+		|| die "Tests failed under ${EPYTHON}"
+	popd > /dev/null
+}
+
+pkg_postinst() {
+	elog "Complete user documentation is available at https://limnoria-doc.readthedocs.org/"
+	elog ""
+	elog "Use supybot-wizard to create a configuration file."
+	elog "Run supybot </path/to/config> to use the bot."
+}