media-sound/mpd: version bump to 0.20.9

2 files changed, 261 insertions, 0 deletions

diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index 93054b61d8a2..15dd425d174b 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -3,3 +3,4 @@ DIST mpd-0.19.21.tar.xz 708512 SHA256 8305b8bc026f4b6bde28b8dd09bfdddbe5590acf36
 DIST mpd-0.20.4.tar.xz 770132 SHA256 712b25351c12616630c580204e1c3dcba3ae2993a56cff1c346c87e334d69728 SHA512 d0c01ae6a3fd59e5ccdc24225bd9bb9e63620f1a395d317573499cc045de81f2abd803ca87eb1b2ca1d26d25167aaa6f5523e96f9512619272b857190efa0a72 WHIRLPOOL 9446b7096c6d2eb41a9421ad8e58e7a70a66e7abb381e75edabf0718c0098646e82ca16d7157e6c453836825eb03a2eca09ff7f80e95918718e42da85ae30c9e
 DIST mpd-0.20.6.tar.xz 772140 SHA256 f4055e1189e5cc00e83706b2e0b5ead924ced0303e073d7802ee9f9a8eba4b47 SHA512 3377e095eaf8cd3ae14e4218fd85d1bcd79d29899ad4c61f5cd2a0b714c5e8aa22aa3b8bd54477195b93ddd44b8e82f8c6428c8f36174c98cba631554224dcfe WHIRLPOOL e3509fb61bed5e766d17ed66178d049bd13b3b088046e7c4d2400d5aebc2d82936ef60297e99db6b386bd474c40caecc3c6d5fd6f703810f3438dce8febfe41f
 DIST mpd-0.20.8.tar.xz 773128 SHA256 7d177f29663c4a0997413401e52bbf11d2bb472773bbcf9294f839c4b8751e35 SHA512 063feafae7137ea5b61498132b4fcc2e04e23bb9d6fa849a0c6d90c40ecc0a841617dec0f53021bfc5add559b59388d20ef211e1bc88fcaca46b5ecbf1bb8960 WHIRLPOOL 2dcc30e9eebdb466486cf6aff93796b2837ede92c5a01f20643ba64af86b9583b1702ac578653d897be3a9cfee2bb5b817584804a2d5192b31920dcdd7a47d62
+DIST mpd-0.20.9.tar.xz 773404 SHA256 cd77a2869e32354b004cc6b34fcb0bee56114caa2d9ed862aaa8071441e34eb7 SHA512 3b29fed4146ca09e3b5866aeea280ca3fb412d182a940da6c1418525e251385fdb18bb58ea99754ad5ba3704a3e2033ff2ef54c392117af7c0be30b78708a2e7 WHIRLPOOL 31fb2302c1165f53848145f6725020ed41aa446653f7132730fbe755d7e19e30266bcbcd61c9cdf6c603db4d34afe64814a887f539e9116ccc2c89054825e1e7
diff --git a/media-sound/mpd/mpd-0.20.9.ebuild b/media-sound/mpd/mpd-0.20.9.ebuild
new file mode 100644
index 000000000000..0b190a1feb8b
--- /dev/null
+++ b/media-sound/mpd/mpd-0.20.9.ebuild
@@ -0,0 +1,260 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils flag-o-matic linux-info multilib systemd user
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/MPD"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sh ~x86 ~x86-fbsd ~x64-macos"
+IUSE="adplug +alsa ao audiofile bzip2 cdio +curl debug +eventfd expat faad
+	+fifo +ffmpeg flac fluidsynth gme +icu +id3tag +inotify +ipv6 jack
+	lame mms libav libmpdclient libsamplerate libsoxr +mad mikmod modplug
+	mpg123 musepack +network nfs ogg openal opus oss pipe pulseaudio recorder
+	samba selinux sid +signalfd sndfile soundcloud sqlite systemd tcpd twolame
+	unicode upnp vorbis wavpack wildmidi zeroconf zip zlib"
+
+OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pulseaudio recorder"
+DECODER_PLUGINS="adplug audiofile faad ffmpeg flac fluidsynth mad mikmod
+	modplug mpg123 musepack ogg flac sid vorbis wavpack wildmidi"
+ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
+
+REQUIRED_USE="
+	|| ( ${OUTPUT_PLUGINS} )
+	|| ( ${DECODER_PLUGINS} )
+	network? ( || ( ${ENCODER_PLUGINS} ) )
+	recorder? ( || ( ${ENCODER_PLUGINS} ) )
+	opus? ( ogg )
+	upnp? ( expat )
+"
+
+CDEPEND="!<sys-cluster/mpich2-1.4_rc2
+	adplug? ( media-libs/adplug )
+	alsa? (
+		media-sound/alsa-utils
+		media-libs/alsa-lib
+	)
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio-paranoia )
+	curl? ( net-misc/curl )
+	expat? ( dev-libs/expat )
+	faad? ( media-libs/faad2 )
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	flac? ( media-libs/flac[ogg?] )
+	fluidsynth? ( media-sound/fluidsynth )
+	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
+	icu? ( dev-libs/icu:= )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( virtual/jack )
+	lame? ( network? ( media-sound/lame ) )
+	libmpdclient? ( media-libs/libmpdclient )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod:0 )
+	mms? ( media-libs/libmms )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( >=media-sound/mpg123-1.12.2 )
+	musepack? ( media-sound/musepack-tools )
+	network? (
+		>=media-libs/libshout-2
+		!lame? ( !vorbis? ( media-libs/libvorbis ) )
+	)
+	nfs? ( net-fs/libnfs )
+	ogg? ( media-libs/libogg )
+	openal? ( media-libs/openal )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( >=net-fs/samba-4.0.25 )
+	sid? ( || ( media-libs/libsidplay:2 media-libs/libsidplayfp ) )
+	sndfile? ( media-libs/libsndfile )
+	soundcloud? ( >=dev-libs/yajl-2:= )
+	libsoxr? ( media-libs/soxr )
+	sqlite? ( dev-db/sqlite:3 )
+	systemd? ( sys-apps/systemd )
+	tcpd? ( sys-apps/tcp-wrappers )
+	twolame? ( media-sound/twolame )
+	upnp? ( net-libs/libupnp:= )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${CDEPEND}
+	dev-libs/boost
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-mpd )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.18.conf.patch
+)
+
+pkg_setup() {
+	use network || ewarn "Icecast and Shoutcast streaming needs networking."
+	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
+
+	enewuser mpd "" "" "/var/lib/mpd" audio
+
+	if use eventfd; then
+		CONFIG_CHECK+=" ~EVENTFD"
+		ERROR_EVENTFD="${P} requires eventfd in-kernel support."
+	fi
+	if use signalfd; then
+		CONFIG_CHECK+=" ~SIGNALFD"
+		ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
+	fi
+	if use inotify; then
+		CONFIG_CHECK+=" ~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+	fi
+	if use eventfd || use signalfd || use inotify; then
+		linux-info_pkg_setup
+	fi
+
+	elog "If you will be starting mpd via /etc/init.d/mpd, please make
+		sure that MPD's pid_file is _set_."
+}
+
+src_prepare() {
+	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-database --disable-roar --disable-documentation
+		--enable-dsd --enable-largefile --disable-osx --disable-shine-encoder
+		--disable-solaris-output --enable-tcp --enable-un --disable-werror
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+	)
+
+	if use network; then
+		myeconfargs+=(
+			--enable-shout
+			$(use_enable vorbis vorbis-encoder)
+			--enable-httpd-output
+			$(use_enable lame lame-encoder)
+			$(use_enable twolame twolame-encoder)
+			$(use_enable audiofile wave-encoder)
+		)
+	else
+		myeconfargs+=(
+			--disable-shout
+			--disable-vorbis-encoder
+			--disable-httpd-output
+			--disable-lame-encoder
+			--disable-twolame-encoder
+			--disable-wave-encoder
+		)
+	fi
+
+	if use samba || use upnp; then
+		myeconfargs+=( --enable-neighbor-plugins )
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+	myeconfargs+=(
+		$(use_enable eventfd)
+		$(use_enable signalfd)
+		$(use_enable libmpdclient)
+		$(use_enable expat)
+		$(use_enable upnp)
+		$(use_enable adplug)
+		$(use_enable alsa)
+		$(use_enable ao)
+		$(use_enable audiofile)
+		$(use_enable zlib)
+		$(use_enable bzip2)
+		$(use_enable cdio cdio-paranoia)
+		$(use_enable curl)
+		$(use_enable samba smbclient)
+		$(use_enable nfs)
+		$(use_enable debug)
+		$(use_enable ffmpeg)
+		$(use_enable fifo)
+		$(use_enable flac)
+		$(use_enable fluidsynth)
+		$(use_enable gme)
+		$(use_enable id3tag id3)
+		$(use_enable inotify)
+		$(use_enable ipv6)
+		$(use_enable cdio iso9660)
+		$(use_enable jack)
+		$(use_enable soundcloud)
+		$(use_enable tcpd libwrap)
+		$(use_enable libsamplerate lsr)
+		$(use_enable libsoxr soxr)
+		$(use_enable mad)
+		$(use_enable mikmod)
+		$(use_enable mms)
+		$(use_enable modplug)
+		$(use_enable musepack mpc)
+		$(use_enable mpg123)
+		$(use_enable openal)
+		$(use_enable opus)
+		$(use_enable oss)
+		$(use_enable pipe pipe-output)
+		$(use_enable pulseaudio pulse)
+		$(use_enable recorder recorder-output)
+		$(use_enable sid sidplay)
+		$(use_enable sndfile sndfile)
+		$(use_enable sqlite)
+		$(use_enable systemd systemd_daemon)
+		$(use_enable vorbis)
+		$(use_enable wavpack)
+		$(use_enable wildmidi)
+		$(use_enable zip zzip)
+		$(use_enable icu)
+		$(use_enable faad aac)
+		$(use_with zeroconf zeroconf avahi)
+		--with-systemdsystemunitdir=$(systemd_get_systemunitdir)
+		--with-systemduserunitdir=$(systemd_get_userunitdir)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	insinto /etc
+	newins doc/mpdconf.dist mpd.conf
+
+	newinitd "${FILESDIR}"/${PN}-0.20.4.init ${PN}
+
+	if use unicode; then
+		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+			"${ED}"/etc/mpd.conf || die "sed failed"
+	fi
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}-0.20.4.logrotate ${PN}
+
+	use prefix || diropts -m0755 -o mpd -g audio
+	dodir /var/lib/mpd
+	keepdir /var/lib/mpd
+	dodir /var/lib/mpd/music
+	keepdir /var/lib/mpd/music
+	dodir /var/lib/mpd/playlists
+	keepdir /var/lib/mpd/playlists
+}
+
+pkg_postinst() {
+	# also change the homedir if the user has existed before
+	usermod -d "/var/lib/mpd" mpd
+}