media-libs/libmediainfo: bump to 22.09

Signed-off-by: Alexis Ballier <aballier@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/media-libs/libmediainfo/Manifest b/media-libs/libmediainfo/Manifest
index f0d40e70ad1a..37bff494f07e 100644
--- a/media-libs/libmediainfo/Manifest
+++ b/media-libs/libmediainfo/Manifest
@@ -1 +1,2 @@
 DIST libmediainfo_22.03.tar.xz 1871232 BLAKE2B 1dd1a1a04adf98dbb3c28cc6fb43e393a4fd32fbc42d110e61d8a72ec8c5603570629e4a756606ccb548873b450944e642b9422f8b00703c91c2832c635e3bd9 SHA512 cae1df09f38e60363ef3c1d0f7324301b701f21c3fde84318f6389f91311b706037699fe83448f8e5b4d1f8af81ddf357b1630fe5f03aeccfa90fe0f9ae86477
+DIST libmediainfo_22.09.tar.xz 1886180 BLAKE2B 3b9fa03ae1fafd06e494ad462ab30a19141c516b6fe61867da7cf339ee470cb56a6cdab57c4e8a498e79c7e3e4b4e5a19b4302f2db2ab0172fe26fefcc0a92f6 SHA512 4204f0ad73f5b826ec89df88607d7e491ecdad512c6bdae12f72b551827b1e4818aa2b88a46a46cb1f8fca46f3638fbe0243e252c685ca46b2d33a9acb00198c
diff --git a/media-libs/libmediainfo/libmediainfo-22.09.ebuild b/media-libs/libmediainfo/libmediainfo-22.09.ebuild
new file mode 100644
index 000000000000..e2292546b188
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-22.09.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Please bump with media-video/mediainfo!
+
+MY_PN="MediaInfo"
+inherit autotools edos2unix flag-o-matic
+
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="https://mediaarea.net/mediainfo/ https://github.com/MediaArea/MediaInfoLib"
+SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+S="${WORKDIR}"/${MY_PN}Lib/Project/GNU/Library
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="curl doc mms"
+
+# Tests try to fetch data from online sources
+RESTRICT="test"
+
+RDEPEND="dev-libs/tinyxml2:=
+	>=media-libs/libzen-0.4.37
+	sys-libs/zlib
+	curl? ( net-misc/curl )
+	mms? ( >=media-libs/libmms-0.6.1 )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	default
+
+	sed -i 's:-O2::' configure.ac || die
+
+	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		--disable-static \
+		--disable-staticlibs \
+		--with-libtinyxml2 \
+		$(use_with curl libcurl) \
+		$(use_with mms libmms)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc || die
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${WORKDIR}"/${MY_PN}Lib/Doc/*.html )
+	fi
+
+	default
+
+	edos2unix ${PN}.pc #414545
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	insinto /usr/include/${MY_PN}DLL
+	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+
+	find "${ED}" -name '*.la' -delete || die
+}