media-libs/harfbuzz: Version bump, bug 566220; fixes tests, bug 567338

Package-Manager: portage-2.2.26

3 files changed, 105 insertions, 3 deletions

diff --git a/media-libs/harfbuzz/Manifest b/media-libs/harfbuzz/Manifest
index 95c4c1b744c8..8d23d58ac89d 100644
--- a/media-libs/harfbuzz/Manifest
+++ b/media-libs/harfbuzz/Manifest
@@ -1,2 +1,3 @@
 DIST harfbuzz-0.9.41.tar.bz2 1188176 SHA256 d81aa53d0c02b437beeaac159d7fc16394d676bbce0860fb6f6a10b587dc057c SHA512 821b2fbd0d668c90e9e0040f60b7cfd8d35954d218045cebfb5e9c6ba29aba4230d0cd8e951697c26afcc4da447177fe967fa323449499fa710b52dd7e1a7011 WHIRLPOOL 84ba899d8fbc27b19d255d3c40e2d1f92c8c0dcc0a764b5c83c8c470af4902891f954d11aa64b6eb69aac0e8cf55c36ee9babff0a9260fc9f6286ce48330accb
 DIST harfbuzz-1.0.6.tar.bz2 1240522 SHA256 f616a7fbdc78a627043f9029000bf08c0c71df59cde4143fc92a014f6a993b26 SHA512 20ee169389a784e4ad4e2ff006a59a36879dba0a37a999ff51c2b4d76da9496a1a747d5176e9611998187452e6d18f880295bdfb9f45338acddf772fc3f16021 WHIRLPOOL 63eab91311674417b66fa92e0b92a5482321dfa8dc48edcc3ae1ed459483222ab08229438356245cc183234a65388fbb6bdb73222359dea0ec2a35a1bf141c78
+DIST harfbuzz-1.1.2.tar.bz2 1233019 SHA256 4a2c5790bd3db7c3ca8c02e4858f2fd592df7932c1d2fa9f6b99acbce0f8461f SHA512 ac2866a3267d7a55311abbdb8f8c38511799c471fb750f203494749ad26edd91ad36c995ee1ce756fa1fcc1625633435cd616e90b794d70f4bb8d213c6d693f9 WHIRLPOOL ef744ddccf30a387823021606304c9f888b99686b397270c2e742191e4c4a885e5872e3c4e8370d0079175a1a026d4c4b21bacf9adf27ccc2837c73294fee121
diff --git a/media-libs/harfbuzz/harfbuzz-1.1.2.ebuild b/media-libs/harfbuzz/harfbuzz-1.1.2.ebuild
new file mode 100644
index 000000000000..cdfd7a5ea536
--- /dev/null
+++ b/media-libs/harfbuzz/harfbuzz-1.1.2.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/harfbuzz"
+[[ ${PV} == 9999 ]] && inherit git-r3 autotools
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils libtool multilib-minimal python-any-r1
+
+DESCRIPTION="An OpenType text shaping engine"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/HarfBuzz"
+[[ ${PV} == 9999 ]] || SRC_URI="http://www.freedesktop.org/software/${PN}/release/${P}.tar.bz2"
+
+LICENSE="Old-MIT ISC icu"
+SLOT="0/0.9.18" # 0.9.18 introduced the harfbuzz-icu split; bug #472416
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos ~x64-solaris"
+
+IUSE="+cairo fontconfig +glib +graphite icu +introspection static-libs test +truetype"
+REQUIRED_USE="introspection? ( glib )"
+
+RDEPEND="
+	cairo? ( x11-libs/cairo:= )
+	fontconfig? ( media-libs/fontconfig:1.0[${MULTILIB_USEDEP}] )
+	glib? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
+	graphite? ( >=media-gfx/graphite2-1.2.1:=[${MULTILIB_USEDEP}] )
+	icu? ( >=dev-libs/icu-51.2-r1:=[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.34:= )
+	truetype? ( >=media-libs/freetype-2.5.0.1:2=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )
+"
+# eautoreconf requires gobject-introspection-common
+# ragel needed if regenerating *.hh files from *.rl
+[[ ${PV} = 9999 ]] && DEPEND="${DEPEND}
+	>=dev-libs/gobject-introspection-common-1.34
+	dev-util/ragel
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	if [[ ${CHOST} == *-darwin* || ${CHOST} == *-solaris* ]] ; then
+		# on Darwin/Solaris we need to link with g++, like automake defaults
+		# to, but overridden by upstream because on Linux this is not
+		# necessary, bug #449126
+		sed -i \
+			-e 's/\<LINK\>/CXXLINK/' \
+			src/Makefile.am || die
+		sed -i \
+			-e '/libharfbuzz_la_LINK = /s/\<LINK\>/CXXLINK/' \
+			src/Makefile.in || die
+		sed -i \
+			-e '/AM_V_CCLD/s/\<LINK\>/CXXLINK/' \
+			test/api/Makefile.in || die
+	fi
+
+	[[ ${PV} == 9999 ]] && eautoreconf
+	elibtoolize # for Solaris
+
+	# failing test, https://bugs.freedesktop.org/show_bug.cgi?id=89190
+	sed -e 's#tests/arabic-fallback-shaping.tests##' -i test/shaping/Makefile.in || die "sed failed"
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" \
+	# harfbuzz-gobject only used for instrospection, bug #535852
+	econf \
+		--without-coretext \
+		--without-uniscribe \
+		$(use_enable static-libs static) \
+		$(multilib_native_use_with cairo) \
+		$(use_with fontconfig) \
+		$(use_with glib) \
+		$(use_with introspection gobject) \
+		$(use_with graphite graphite2) \
+		$(use_with icu) \
+		$(multilib_native_use_enable introspection) \
+		$(use_with truetype freetype)
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/docs/html docs/html || die
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --modules
+}
diff --git a/media-libs/harfbuzz/harfbuzz-9999.ebuild b/media-libs/harfbuzz/harfbuzz-9999.ebuild
index 7b0789786d53..cdfd7a5ea536 100644
--- a/media-libs/harfbuzz/harfbuzz-9999.ebuild
+++ b/media-libs/harfbuzz/harfbuzz-9999.ebuild
@@ -19,15 +19,17 @@ LICENSE="Old-MIT ISC icu"
 SLOT="0/0.9.18" # 0.9.18 introduced the harfbuzz-icu split; bug #472416
 [[ ${PV} == 9999 ]] || \
 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos ~x64-solaris"
-IUSE="+cairo +glib +graphite icu +introspection static-libs test +truetype"
+
+IUSE="+cairo fontconfig +glib +graphite icu +introspection static-libs test +truetype"
 REQUIRED_USE="introspection? ( glib )"
 
 RDEPEND="
 	cairo? ( x11-libs/cairo:= )
+	fontconfig? ( media-libs/fontconfig:1.0[${MULTILIB_USEDEP}] )
 	glib? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
 	graphite? ( >=media-gfx/graphite2-1.2.1:=[${MULTILIB_USEDEP}] )
 	icu? ( >=dev-libs/icu-51.2-r1:=[${MULTILIB_USEDEP}] )
-	introspection? ( >=dev-libs/gobject-introspection-1.34 )
+	introspection? ( >=dev-libs/gobject-introspection-1.34:= )
 	truetype? ( >=media-libs/freetype-2.5.0.1:2=[${MULTILIB_USEDEP}] )
 "
 DEPEND="${RDEPEND}
@@ -77,6 +79,7 @@ multilib_src_configure() {
 		--without-uniscribe \
 		$(use_enable static-libs static) \
 		$(multilib_native_use_with cairo) \
+		$(use_with fontconfig) \
 		$(use_with glib) \
 		$(use_with introspection gobject) \
 		$(use_with graphite graphite2) \
@@ -85,7 +88,7 @@ multilib_src_configure() {
 		$(use_with truetype freetype)
 
 	if multilib_is_native_abi; then
-		ln -s "${S}"/docs/reference/html docs/reference/html || die
+		ln -s "${S}"/docs/html docs/html || die
 	fi
 }