media-libs/babl: 0.1.98 version bump

Signed-off-by: Sergey Torokhov <torokhov-s-a@yandex.ru>
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 72 insertions, 2 deletions

diff --git a/media-libs/babl/Manifest b/media-libs/babl/Manifest
index 626612e6328b..ba4ddf504fa2 100644
--- a/media-libs/babl/Manifest
+++ b/media-libs/babl/Manifest
@@ -1,2 +1,3 @@
 DIST babl-0.1.92.tar.xz 309784 BLAKE2B c3c716ba1b54082743ba6ea33da99fb458dc971ab78ae72170af9840eadbc7f2aeb0a26d3270ede2a6e0d7b55489fc8f700b1c69731a4612ba4106f9672762d0 SHA512 c2baf39f576bf7f57786c59f2de0818257f4d1d62cadf44fdd802c9a534ed94390dd1616e7e72fcc9de1fb85a24a10fbacdbbabbe376a45ae598be46817e3bc0
 DIST babl-0.1.96.tar.xz 312184 BLAKE2B 6ee307054cf4d1e0f434a6070189ed143c60056decb59184f880b26863c8177d0c69294254651923f7dfb897555939602e6f4384e7561a839a3cf80ae9468859 SHA512 771d68b80f1123baa38256e4b1d7946284cd88997b2ab7c7092a74120e91ea5ee7ab4c001686ae4b3e363b6465484f185a64f9c75515a55d3ffb81fecbeaca42
+DIST babl-0.1.98.tar.xz 312516 BLAKE2B c12626e4b8127a5b2e17507e20cf6ce324834a58d64fa54b80fbe00ef2468d3d29c870d44a22f08f7e74404cf6f47321084c854a4ba017cf0c8c199d8210849f SHA512 33b2e3f8fbcd6602bb82d6242dd2911bb2232e69350f7a0e70e14b1472052e27b0e2a1fa6a2b6d0449fc9796353336e311c8d4007c532447cd61f95b684a3120
diff --git a/media-libs/babl/babl-0.1.98.ebuild b/media-libs/babl/babl-0.1.98.ebuild
new file mode 100644
index 000000000000..b0809b33eff6
--- /dev/null
+++ b/media-libs/babl/babl-0.1.98.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VALA_USE_DEPEND=vapigen
+
+inherit meson gnome2-utils vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/babl.git"
+	SRC_URI=""
+else
+	SRC_URI="https://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv -sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A dynamic, any to any, pixel format conversion library"
+HOMEPAGE="https://gegl.org/babl/"
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="introspection lcms vala cpu_flags_x86_avx2 cpu_flags_x86_f16c cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse4_1"
+REQUIRED_USE="vala? ( introspection )"
+
+BDEPEND="
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+RDEPEND="
+	introspection? ( >=dev-libs/gobject-introspection-1.72:= )
+	lcms? ( >=media-libs/lcms-2.13.1:2 )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	gnome2_environment_reset
+}
+
+src_configure() {
+	use vala && vala_setup
+
+	# Automagic rsvg support is just for website generation we do not call,
+	#     so we don't need to fix it
+	# w3m is used for dist target thus no issue for us that it is automagically
+	#     detected
+	local emesonargs=(
+		-Dwith-docs=false
+		$(meson_use introspection enable-gir)
+		$(meson_use lcms with-lcms)
+		$(meson_use vala enable-vapi)
+		$(meson_use cpu_flags_x86_avx2 enable-avx2)
+		$(meson_use cpu_flags_x86_f16c enable-f16c)
+		$(meson_use cpu_flags_x86_mmx enable-mmx)
+		$(meson_use cpu_flags_x86_sse enable-sse)
+		$(meson_use cpu_flags_x86_sse2 enable-sse2)
+		$(meson_use cpu_flags_x86_sse4_1 enable-sse4_1)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# Bug 871690
+	dosym -r /usr/"$(get_libdir)"/pkgconfig/babl.pc /usr/"$(get_libdir)"/pkgconfig/babl-0.1.pc
+}
diff --git a/media-libs/babl/babl-9999.ebuild b/media-libs/babl/babl-9999.ebuild
index d97d11c00c37..c2f6e632a595 100644
--- a/media-libs/babl/babl-9999.ebuild
+++ b/media-libs/babl/babl-9999.ebuild
@@ -29,8 +29,8 @@ BDEPEND="
 	vala? ( $(vala_depend) )
 "
 RDEPEND="
-	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
-	lcms? ( >=media-libs/lcms-2.8:2 )
+	introspection? ( >=dev-libs/gobject-introspection-1.72:= )
+	lcms? ( >=media-libs/lcms-2.13.1:2 )
 "
 DEPEND="${RDEPEND}"