media-gfx/mcomix: bump with snapshot from python3 fork

This fork is already in use in other distributions to allow python 3
packaging, including Debian and Fedora. Do the same in Gentoo

Also fix live ebuild blocker

Bug: https://bugs.gentoo.org/708100
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

3 files changed, 80 insertions, 2 deletions

diff --git a/media-gfx/mcomix/Manifest b/media-gfx/mcomix/Manifest
index 1b622f82878b..29d4b5c1feca 100644
--- a/media-gfx/mcomix/Manifest
+++ b/media-gfx/mcomix/Manifest
@@ -1 +1,2 @@
 DIST mcomix-1.2.1.tar.bz2 571128 BLAKE2B fa00e55e5cf2ef676a625b97ca467ade6b629fa08bfd920b8c370dc7d33c6602c5614d120d7279df32d063db646da8b635712ba90793175eea2c74c2c1973a8a SHA512 efa4d57edc3a48d9e711767fb3e233ef9b334ff8ba467999e572e60ed747a4ee4aa420c8aa7788b16d7eb6e0901d454d6a405fcec47a8c74098a49491e915cd0
+DIST mcomix-1.3.0_pre20200206.tar.gz 3292571 BLAKE2B ad76316020645495042d27bf831588e628da11077efe29b302a57be4e688558b4db8d3f850200bf4a54b84b428a16a52f88ea5e20be85b628ef3630a5f624643 SHA512 c98d4a7022993af3a5c0b5425df52f14b586549472bcd4576a72039c8c6d4fde31df4255df45ab7467acb0280bda02b92d4803b7f92b7c1c818b58df7b52a3ff
diff --git a/media-gfx/mcomix/mcomix-1.3.0_pre20200206.ebuild b/media-gfx/mcomix/mcomix-1.3.0_pre20200206.ebuild
new file mode 100644
index 000000000000..dcfc08d61190
--- /dev/null
+++ b/media-gfx/mcomix/mcomix-1.3.0_pre20200206.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8} )
+inherit desktop python-r1 xdg
+
+# Hash used for this version
+GIT_PV="b80f3485b6ec324aec1dc20f28296a8891ad70dd"
+
+DESCRIPTION="GTK image viewer for comic book archives"
+HOMEPAGE="https://github.com/multiSnow/mcomix3"
+SRC_URI="https://github.com/multiSnow/mcomix3/archive/${GIT_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	virtual/jpeg
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pygobject[${PYTHON_USEDEP}]
+	!media-gfx/comix"
+BDEPEND="sys-devel/gettext"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+S=${WORKDIR}/mcomix3-${GIT_PV}
+
+src_prepare() {
+	default
+
+	for file in mcomix/mcomix/messages/*/LC_MESSAGES/*po
+	do
+		msgfmt ${file} -o ${file/po/mo} || die
+		rm ${file} || die
+	done
+}
+
+src_install() {
+	python_foreach_impl python_domodule mcomix/mcomix
+	python_foreach_impl python_newscript mcomix/mcomixstarter.py mcomix
+
+	for size in 16 22 24 32 48
+	do
+		doicon -s ${size} \
+			mime/icons/${size}x${size}/*png \
+			mcomix/mcomix/images/${size}x${size}/mcomix.png
+	done
+	doicon mcomix/mcomix/images/mcomix.png
+	domenu mime/mcomix.desktop
+	doman man/mcomix.1
+
+	insinto /usr/share/metainfo
+	doins mime/mcomix.appdata.xml
+
+	insinto /usr/share/mime/packages
+	doins mime/mcomix.xml
+
+	dodoc README.rst TODO
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	echo
+	elog "Additional packages are required to open the most common comic archives:"
+	elog
+	elog "    cbr: app-arch/unrar"
+	elog "    cbz: app-arch/unzip"
+	elog
+	elog "You can also add support for 7z or LHA archives by installing"
+	elog "app-arch/p7zip or app-arch/lha. Install app-text/mupdf for"
+	elog "pdf support."
+	echo
+}
diff --git a/media-gfx/mcomix/mcomix-9999.ebuild b/media-gfx/mcomix/mcomix-9999.ebuild
index 6dd55b82b07f..15afb7c558eb 100644
--- a/media-gfx/mcomix/mcomix-9999.ebuild
+++ b/media-gfx/mcomix/mcomix-9999.ebuild
@@ -20,8 +20,7 @@ RDEPEND="${DEPEND}
 	virtual/jpeg
 	dev-python/pillow[${PYTHON_USEDEP}]
 	dev-python/pygobject[${PYTHON_USEDEP}]
-	!media-gfx/comix
-	!media-gfx/mcomix"
+	!media-gfx/comix"
 BDEPEND="sys-devel/gettext"
 
 REQUIRED_USE=${PYTHON_REQUIRED_USE}