kde-apps: Add KDE Release Service 20.04.2

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index 632f97f06f52..46dcf483dc8f 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-19.12.3.tar.xz 6194476 BLAKE2B 98dfcc9922757441b4fbb998f6b2c8c74c14da82ac4811e9b705ba2f6fecd812e2fab8dc840d013be79bcd9b229c432bdb3f938fa6abd933a8898a1593d373ae SHA512 33c045e85aebc4e7ef599a801ebeaf413ce4335fafce109a542cd8af5f83f3748d603698aab48586824cb12a573c6325d7ee20e78d6492a990e7a6650c67e9ba
 DIST kwave-20.04.1.tar.xz 6195960 BLAKE2B f667983abe6b62dd761a40283bffa5713b40cf34426b28e8d0d65f1c7beb6842fbaedf3453b8224067ce43a79d53ddcefd63f76b8c88ed1cc74628ec34214d5f SHA512 fbf657cc5c1246d574b28d56a305694d614ab4c88ee438920ba75ec53944171eec1ba20d7269e710979cdf406c35c1f3ace355dad3881f01bf9e3e75f03a264e
+DIST kwave-20.04.2.tar.xz 6195816 BLAKE2B 697ec18ad8d2fd1f5417629bc15cf091ba975861b297572e06f707c9dbb6878613935988c04e21d80d4f158b2a8a56f4bd11779896bfc66cc2306233a0ee4c89 SHA512 7a2697ca87533858af7bc8943c3ac1c7a31acf6d977fd311035bb129e4d8133987bc4ba2cd44d442b29bec2db9b743fde9ded39981e4d6d5d339c504719c2691
diff --git a/kde-apps/kwave/kwave-20.04.2.ebuild b/kde-apps/kwave/kwave-20.04.2.ebuild
new file mode 100644
index 000000000000..b97d5b14e6e6
--- /dev/null
+++ b/kde-apps/kwave/kwave-20.04.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.70.0
+QTMIN=5.14.1
+inherit ecm kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://kde.org/applications/multimedia/org.kde.kwave"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}