kde-apps/kate-addons: drop 22.08.0-r1

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 113 deletions

diff --git a/kde-apps/kate-addons/Manifest b/kde-apps/kate-addons/Manifest
index ac35aa607543..26af48b28a28 100644
--- a/kde-apps/kate-addons/Manifest
+++ b/kde-apps/kate-addons/Manifest
@@ -1,2 +1 @@
-DIST kate-22.08.0.tar.xz 7655384 BLAKE2B 7f8ccf67f6e29c3047b3ad4cdbd28d373d35b5d4cb580aa29097229ad5910ed2393fe97acc742c755a4b35711086aaa55c698fc3fe3fbd0d3e64d9df021b15e8 SHA512 637e5314cabe87efdd6f8162b955d9b369a6bc12e77006325dd3038d517208ef5aca457ca2932cd37c1f98301b7a1968f30859e5c7a5cb16ce0b974910d7c5bc
 DIST kate-22.08.1.tar.xz 7663600 BLAKE2B 673007f2ce17b6dd3c8525a903eccc116a252ccd45121a2829a1830eaa97e88be81f73f41c1434b596cc5f69b6680a8a0d873257467c311671c41b20a6e10086 SHA512 cdea4ae0ad0ff8f8b2c4a75e253d16d4048e17f2d778534862fd7e77f99824c4d046dc3e667dc093153e9c3c662a4d911deef7d88f24d41456b786ec7b58f878
diff --git a/kde-apps/kate-addons/kate-addons-22.08.0-r1.ebuild b/kde-apps/kate-addons/kate-addons-22.08.0-r1.ebuild
deleted file mode 100644
index 84aad14fc16a..000000000000
--- a/kde-apps/kate-addons/kate-addons-22.08.0-r1.ebuild
+++ /dev/null
@@ -1,112 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-KDE_ORG_CATEGORY="utilities"
-KDE_ORG_NAME="kate"
-ECM_TEST="true"
-KFMIN=5.96.0
-QTMIN=5.15.5
-VIRTUALX_REQUIRED="test"
-inherit ecm flag-o-matic gear.kde.org optfeature
-
-DESCRIPTION="Addons used by Kate"
-HOMEPAGE="https://kate-editor.org/ https://apps.kde.org/kate/"
-
-LICENSE="LGPL-2 LGPL-2+ MIT"
-SLOT="5"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
-IUSE="+filebrowser lspclient plasma +projects +snippets sql"
-
-DEPEND="
-	>=dev-qt/qtconcurrent-${QTMIN}:5
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtnetwork-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=dev-qt/qtxml-${QTMIN}:5
-	~kde-apps/kate-lib-${PV}:5
-	>=kde-frameworks/kcodecs-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/kguiaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kiconthemes-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kitemviews-${KFMIN}:5
-	>=kde-frameworks/kjobwidgets-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/ktexteditor-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kwindowsystem-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
-	filebrowser? ( >=kde-frameworks/kbookmarks-${KFMIN}:5 )
-	lspclient? ( >=kde-frameworks/kitemmodels-${KFMIN}:5 )
-	plasma? ( >=kde-frameworks/plasma-${KFMIN}:5 )
-	projects? (
-		>=kde-frameworks/knewstuff-${KFMIN}:5
-		>=kde-frameworks/threadweaver-${KFMIN}:5
-	)
-	snippets? ( >=kde-frameworks/knewstuff-${KFMIN}:5 )
-	sql? (
-		>=dev-qt/qtsql-${QTMIN}:5
-		>=kde-frameworks/kwallet-${KFMIN}:5
-	)
-"
-RDEPEND="${DEPEND}
-	!<kde-apps/kate-22.08.0:5
-"
-
-src_prepare() {
-	ecm_src_prepare
-
-	# these tests are run in kde-apps/kate-lib
-	cmake_run_in apps/lib cmake_comment_add_subdirectory autotests
-
-	# delete colliding libkate/kwrite translations
-	if [[ ${KDE_BUILD_TYPE} = release ]]; then
-		find po -type f -name "*po" -and \( -name "kwrite*" -or -name "kate.po" \) -delete || die
-		rm -rf po/*/docs || die
-	fi
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_kate=FALSE
-		-DBUILD_kwrite=FALSE
-		-DCMAKE_DISABLE_FIND_PACKAGE_KF5DocTools=ON # docs in kate/kwrite
-		-DBUILD_filebrowser=$(usex filebrowser)
-		-DBUILD_lspclient=$(usex lspclient)
-		-DBUILD_sessionapplet=$(usex plasma)
-		-DBUILD_project=$(usex projects)
-		-DBUILD_snippets=$(usex snippets)
-		-DBUILD_katesql=$(usex sql)
-	)
-
-	# provided by kde-apps/kate-lib
-	append-libs -lkateprivate
-
-	ecm_src_configure
-}
-
-src_install() {
-	ecm_src_install
-
-	# provided by kde-apps/kate-lib
-	rm -v "${ED}"/usr/$(get_libdir)/libkateprivate.so.* || die
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "Markdown text previews" kde-misc/markdownpart:${SLOT} kde-misc/kmarkdownwebview:${SLOT}
-		optfeature "DOT graph file previews" media-gfx/kgraphviewer
-	fi
-	ecm_pkg_postinst
-}