kde-apps/cantor: 20.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 106 insertions, 0 deletions

diff --git a/kde-apps/cantor/Manifest b/kde-apps/cantor/Manifest
index 334e588aa450..502992630366 100644
--- a/kde-apps/cantor/Manifest
+++ b/kde-apps/cantor/Manifest
@@ -1 +1,2 @@
 DIST cantor-20.08.3.tar.xz 9082332 BLAKE2B 7ea84959559e109a28794d1f610e07936de353c08e7732a90c6f8145828df99d6b408006580e367208e135c3d76530bdb02716c873a4adf491912ef07b470350 SHA512 8558bb6b3e6641c1c575a4f5f0b1db7f6d6003ed011432f555ee0954586f0cd3a0d1d897d55114dd29cd9aa58d7e6d7ffb9a2357b1e96c01bbf2b4f3623174dd
+DIST cantor-20.12.0.tar.xz 9102652 BLAKE2B b4abda0e34abc34bd46fe3a5d2ae79a6a3d9d601f3118bb7ef7e20afbdd2ad7d4b6477ece2bcafaf65a9755fa17d34cad8ba5378d55a5cd25ff385bfe6324d17 SHA512 1edea13034d4b9038feb66ee3b8e1f938cced7e30bdd5de1fe5007f5b32e3c5bec1f27bce2ca5bdaa228b9abaa486a044c6be230e19d0310e7adaa7b3b2826b4
diff --git a/kde-apps/cantor/cantor-20.12.0.ebuild b/kde-apps/cantor/cantor-20.12.0.ebuild
new file mode 100644
index 000000000000..f8c2cd2064cc
--- /dev/null
+++ b/kde-apps/cantor/cantor-20.12.0.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+PYTHON_COMPAT=( python3_{7,8,9} )
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.75.0
+QTMIN=5.15.1
+inherit ecm kde.org optfeature python-single-r1
+
+DESCRIPTION="Interface for doing mathematics and scientific computing"
+HOMEPAGE="https://apps.kde.org/en/cantor https://edu.kde.org/cantor/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+analitza julia lua postscript python qalculate R"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# TODO Add Sage Mathematics Software backend (http://www.sagemath.org)
+DEPEND="
+	app-text/poppler[qt5]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=dev-qt/qtxmlpatterns-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
+	analitza? ( >=kde-apps/analitza-${PVCUT}:5 )
+	julia? ( dev-lang/julia )
+	lua? ( dev-lang/luajit:2 )
+	qalculate? (
+		sci-libs/cln
+		sci-libs/libqalculate:=
+	)
+	postscript? ( app-text/libspectre )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-qt/qtdbus-${QTMIN}:5
+	)
+	R? ( dev-lang/R )
+"
+RDEPEND="${DEPEND}
+	!analitza? ( !julia? ( !lua? ( !python? ( !qalculate? ( !R? (
+		|| (
+			sci-mathematics/maxima
+			sci-mathematics/octave
+		)
+	) ) ) ) ) )
+"
+
+RESTRICT+=" test"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	use julia && addpredict /proc/self/mem # bug 602894
+
+	local mycmakeargs=(
+		$(cmake_use_find_package analitza Analitza5)
+		$(cmake_use_find_package julia Julia)
+		$(cmake_use_find_package lua LuaJIT)
+		-DUSE_LIBSPECTRE=$(usex postscript)
+		$(cmake_use_find_package python Python3)
+		$(cmake_use_find_package qalculate Qalculate)
+		$(cmake_use_find_package R R)
+	)
+	use python && mycmakeargs+=( -DPython3_EXECUTABLE="${PYTHON}" )
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "Optional dependencies:"
+		optfeature "Maxima backend" sci-mathematics/maxima
+		optfeature "Octave backend" sci-mathematics/octave
+		optfeature "LaTeX support" virtual/latex-base
+	fi
+	ecm_pkg_postinst
+}