games-puzzle/triptych: Move from triptych-demo, SRC_URI fix, EAPI 7

The full version and demo version are actually the same. You obtain
registration details by ordering online.

This is not a version bump. The previous ebuild used the same tarball
but had version 0 despite the game reporting 1.16.

Closes: https://bugs.gentoo.org/640572
Package-Manager: Portage-2.3.40, Repoman-2.3.9

3 files changed, 72 insertions, 0 deletions

diff --git a/games-puzzle/triptych/Manifest b/games-puzzle/triptych/Manifest
new file mode 100644
index 000000000000..afa274c4eced
--- /dev/null
+++ b/games-puzzle/triptych/Manifest
@@ -0,0 +1 @@
+DIST triptych.tar.gz 1748316 BLAKE2B 0d66265df27f61ddee1e1777a1e749d3a8bbcebf0e2bfe64a054febb48def865b68ab59d9c25804ed725bb11d24af2bbd712cc2de88a7259db26aa6d7c3c8d1f SHA512 614de78c9f90dd2145ff3dfa6f7a799a069c5add80bc8b0494a752346a163ab0eff7b707292b815adbffa34e4fec446035cfb65df4dd6cf284f270bb732b6daa
diff --git a/games-puzzle/triptych/metadata.xml b/games-puzzle/triptych/metadata.xml
new file mode 100644
index 000000000000..78274e0fa550
--- /dev/null
+++ b/games-puzzle/triptych/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>games@gentoo.org</email>
+	<name>Gentoo Games Project</name>
+</maintainer>
+</pkgmetadata>
diff --git a/games-puzzle/triptych/triptych-1.16.ebuild b/games-puzzle/triptych/triptych-1.16.ebuild
new file mode 100644
index 000000000000..e2257e17ad3f
--- /dev/null
+++ b/games-puzzle/triptych/triptych-1.16.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop eutils user
+
+DESCRIPTION="Fast-paced Tetris-like puzzler"
+HOMEPAGE="http://www.chroniclogic.com/triptych.htm"
+SRC_URI="http://www.chroniclogic.com/demos/${PN}.tar.gz"
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+RESTRICT="bindist mirror strip"
+
+RDEPEND=">=media-libs/libsdl-1.2[abi_x86_32,opengl,sound,video]
+	virtual/opengl[abi_x86_32]
+	x11-libs/libX11[abi_x86_32]
+	x11-libs/libXext[abi_x86_32]"
+
+QA_PREBUILT="opt/${PN}/${PN}
+	opt/${PN}/setup"
+
+S="${WORKDIR}/${PN}"
+
+DIR="/opt/${PN}"
+WRITABLE=( "${EROOT}${DIR}"/{hwconfig.cfg,${PN}.{clr,cnt,scr}} )
+
+pkg_setup() {
+	enewgroup gamestat 36
+}
+
+src_prepare() {
+	default
+	rm -v *.dll || die
+}
+
+src_install() {
+	local EXES=( ${PN} setup )
+
+	insinto "${DIR}"
+	doins -r .
+
+	exeinto "${DIR}"
+	doexe "${EXES[@]}"
+
+	fowners root:gamestat "${EXES[@]/#/${DIR}/}" || die
+	fperms g+s "${EXES[@]/#/${DIR}/}" || die
+
+	make_wrapper ${PN} ./${PN} "${DIR}"
+	make_wrapper ${PN}-setup ./setup "${DIR}"
+}
+
+pkg_postinst() {
+	touch "${WRITABLE[@]}" || die
+	chown root:gamestat "${WRITABLE[@]}" || die
+	chmod 0664 "${WRITABLE[@]}" || die
+}
+
+pkg_prerm() {
+	[[ -z ${REPLACED_BY_VERSION} ]] &&
+		rm -v "${WRITABLE[@]}"
+}