dev-util/promu: update to use the go-module eclass

This is a build time change, so it will not affect a live system.
Signed-off-by: William Hubbs <williamh@gentoo.org>

1 files changed, 10 insertions, 13 deletions

diff --git a/dev-util/promu/promu-0.5.0.ebuild b/dev-util/promu/promu-0.5.0.ebuild
index 7ede34ae7c3a..64f6ce821f01 100644
--- a/dev-util/promu/promu-0.5.0.ebuild
+++ b/dev-util/promu/promu-0.5.0.ebuild
@@ -1,35 +1,32 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-inherit golang-build golang-vcs-snapshot
+EAPI=7
+inherit go-module
 
-EGO_PN="github.com/prometheus/promu"
 EGIT_COMMIT="642a960b363a409efff7621dbf5b183d58670ec2"
-SRC_URI="https://${EGO_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-KEYWORDS="amd64"
 
 DESCRIPTION="Prometheus Utility Tool"
 HOMEPAGE="https://github.com/prometheus/promu"
+SRC_URI="https://github.com/prometheus/promu/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
 LICENSE="Apache-2.0 BSD BSD-2 MIT"
 SLOT="0"
+KEYWORDS="amd64"
 IUSE=""
-RESTRICT="test"
 
-DEPEND=">=dev-lang/go-1.12"
+RESTRICT+=" test"
 
 src_prepare() {
 	default
-	sed -i -e "s/{{.Revision}}/${EGIT_COMMIT}/" src/${EGO_PN}/.promu.yml || die
+	sed -i -e "s/{{.Revision}}/${EGIT_COMMIT}/" .promu.yml || die
 }
 
 src_compile() {
-	pushd src/${EGO_PN} || die
-	GO111MODULE=off GOCACHE="${T}/go-cache" GOPATH="${S}" go install -v github.com/prometheus/promu || die
-	popd || die
+	go build -mod=vendor . || die "compile failed"
 }
 
 src_install() {
-	dobin bin/*
-	dodoc -r src/${EGO_PN}/{doc,{README,CONTRIBUTING}.md}
+	dobin ${PN}
+	dodoc -r {doc,{README,CONTRIBUTING}.md}
 }