dev-ruby/sinatra: enable ruby32, fix tests

Closes: https://bugs.gentoo.org/893182
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-ruby/sinatra/sinatra-3.0.5-r1.ebuild b/dev-ruby/sinatra/sinatra-3.0.5-r1.ebuild
new file mode 100644
index 000000000000..c7a9a21dcf65
--- /dev/null
+++ b/dev-ruby/sinatra/sinatra-3.0.5-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby27 ruby30 ruby31"
+
+RUBY_FAKEGEM_TASK_TEST="MT_NO_PLUGINS=true test:core"
+
+RUBY_FAKEGEM_EXTRADOC="README.md AUTHORS.md CHANGELOG.md"
+
+RUBY_FAKEGEM_GEMSPEC="sinatra.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A DSL for quickly creating web applications in Ruby with minimal effort"
+HOMEPAGE="https://sinatrarb.com/"
+SRC_URI="https://github.com/sinatra/sinatra/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
+IUSE=""
+
+ruby_add_rdepend "
+	dev-ruby/mustermann:3
+	>=dev-ruby/rack-2.2.4:2.2
+	~dev-ruby/rack-protection-${PV}
+	dev-ruby/tilt:2"
+ruby_add_bdepend "
+	test? (
+		dev-ruby/builder
+		dev-ruby/erubi
+		dev-ruby/haml
+		>=dev-ruby/rack-test-0.5.6
+		<dev-ruby/activesupport-7
+	)
+"
+ruby_add_bdepend "doc? ( dev-ruby/yard )"
+
+all_ruby_prepare() {
+	# Matching dev-ruby/activesupport
+	sed -i -e '/minitest.*~> 5.0/s:.*:&, "< 5.16":' Gemfile || die
+
+	sed -i \
+		-e "/require 'rack'/igem 'rack', '~> 2.2', '>= 2.2.4'" \
+		-e "/require 'minitest'/igem 'minitest', '< 5.16'" \
+		-e '/active_support\/core_ext\/hash/igem "activesupport", "<7"' \
+		test/helper.rb || die
+
+	# Avoid spec broken by newer rack versions, already removed upstream.
+	sed -i -e 's/"bytes=IV-LXVI", //' test/static_test.rb || die
+}