dev-ruby/redcloth: add ruby30; drop unused versionator eclass

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 61 insertions, 0 deletions

diff --git a/dev-ruby/redcloth/redcloth-4.3.2-r2.ebuild b/dev-ruby/redcloth/redcloth-4.3.2-r2.ebuild
new file mode 100644
index 000000000000..e442db0353e6
--- /dev/null
+++ b/dev-ruby/redcloth/redcloth-4.3.2-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+USE_RUBY="ruby25 ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_NAME="RedCloth"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+RUBY_FAKEGEM_TASK_DOC=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="README.rdoc CHANGELOG"
+
+RUBY_FAKEGEM_REQUIRE_PATHS="lib/case_sensitive_require"
+
+RUBY_FAKEGEM_GEMSPEC=redcloth.gemspec
+
+inherit ruby-fakegem
+
+DESCRIPTION="A module for using Textile in Ruby"
+HOMEPAGE="http://redcloth.org/"
+
+GITHUB_USER=jgarber
+SRC_URI="https://github.com/${GITHUB_USER}/redcloth/archive/v${PV}.tar.gz -> ${RUBY_FAKEGEM_NAME}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+DEPEND+=" =dev-util/ragel-6*"
+
+PATCHES=( "${FILESDIR}/${P}-load-documents.patch" )
+
+ruby_add_bdepend "
+	>=dev-ruby/rake-0.8.7
+	>=dev-ruby/rake-compiler-0.7.1
+	test? ( >=dev-ruby/diff-lcs-1.1.2 )"
+
+pkg_setup() {
+	ruby-ng_pkg_setup
+
+	# Export the VERBOSE variable to avoid remapping of stdout and
+	# stderr, and that breaks because of bad interactions between
+	# echoe, Ruby and Gentoo.
+	export VERBOSE=1
+}
+
+all_ruby_prepare() {
+	sed -i -e '/[Bb]undler/d' Rakefile ${PN}.gemspec || die
+	rm -f tasks/{release,rspec,rvm}.rake || die
+}
+
+each_ruby_compile() {
+	# We cannot run this manually easily, because Ragel re-generation
+	# is a mess
+	${RUBY} -S rake compile || die "rake compile failed"
+}