dev-ruby/addressable: add ruby23

Package-Manager: portage-2.2.28

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-ruby/addressable/addressable-2.4.0-r1.ebuild b/dev-ruby/addressable/addressable-2.4.0-r1.ebuild
new file mode 100644
index 000000000000..3e05122bd62b
--- /dev/null
+++ b/dev-ruby/addressable/addressable-2.4.0-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+USE_RUBY="ruby20 ruby21 ruby22 ruby23"
+
+RUBY_FAKEGEM_TASK_DOC="doc:yard"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RAKE_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="README.md CHANGELOG.md"
+
+RUBY_FAKEGEM_EXTRAINSTALL="data"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A replacement for the URI implementation that is part of Ruby's standard library"
+HOMEPAGE="https://rubygems.org/gems/addressable https://github.com/sporkmonger/addressable"
+
+LICENSE="Apache-2.0"
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="doc test"
+
+ruby_add_bdepend "doc? ( dev-ruby/yard )"
+ruby_add_bdepend "test? ( dev-ruby/rspec-its )"
+
+all_ruby_prepare() {
+	# Remove spec-related tasks so that we don't need to require rspec
+	# just to build the documentation, bug 383611.
+	sed -i -e '/spectask/d' Rakefile || die
+	rm -f tasks/rspec.rake || die
+	sed -i -e '/bundler/ s:^:#:' \
+		-e '/^begin/,/^end/ s:^:#:' \
+		spec/spec_helper.rb || die
+
+	# Remove specs requiring network connectivity
+	rm -f spec/addressable/net_http_compat_spec.rb || die
+
+	# Remove spec that tests against an unreleased github fork
+	rm -f spec/addressable/rack_mount_compat_spec.rb || die
+}