dev-ruby/activejob: add 5.2.8.1

Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-ruby/activejob/activejob-5.2.8.1.ebuild b/dev-ruby/activejob/activejob-5.2.8.1.ebuild
new file mode 100644
index 000000000000..eb33a18e38f9
--- /dev/null
+++ b/dev-ruby/activejob/activejob-5.2.8.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27"
+
+RUBY_FAKEGEM_TASK_TEST="MT_NO_PLUGINS=true"
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_DOCDIR=""
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Job framework with pluggable queues"
+HOMEPAGE="https://github.com/rails/rails"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux"
+IUSE=""
+
+RUBY_S="rails-${PV}/${PN}"
+
+ruby_add_rdepend "
+	~dev-ruby/activesupport-${PV}
+	>=dev-ruby/globalid-0.3.6
+"
+
+ruby_add_bdepend "
+	test? (
+		dev-ruby/mocha
+	)"
+
+all_ruby_prepare() {
+	# Set test environment to our hand.
+	sed -i -e '/load_paths/d' test/helper.rb || die "Unable to remove load paths"
+	sed -i -e '2igem "activesupport", "~> 5.2.0"' test/helper.rb || die
+
+	# Remove all currently unpackaged queues.
+	sed -i -e 's/que queue_classic resque sidekiq sneakers sucker_punch backburner//' \
+		-e 's/delayed_job//' Rakefile || die
+}