dev-python/tox: Bump to 4.3.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 6b1a31881060..a6df2555bb90 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -2,3 +2,4 @@ DIST tox-3.27.1.gh.tar.gz 309006 BLAKE2B fa8aaa9cd5b03e54c166bb6b748290420b91498
 DIST tox-3.28.0.gh.tar.gz 309472 BLAKE2B 9896411426f6aebb3efa468c01696ecc5f17ec3e67825672d0efc74c1b1468bc8b8d9c14b6177c181750ba4b9a5e77d616068dd83e21f5641acfc8e2a271cc1f SHA512 64816754e6800661bb564c5c7d21c4139522d540a04fafe3c4591d596072d48d1cbe0ee2abee9c8faf3d5007774f5371431b5a7a8f49912bc879c7b168aab2ca
 DIST tox-4.3.0.gh.tar.gz 296472 BLAKE2B 695efd31fef5f9aeb1bce71d95e913c38b9cb0dce0bcd955d85b492142088b89b59ab2a09754189959488042c1dfc6e476b17ebcb72a1b6ce2e9add8b764d6d0 SHA512 4ec09f4b43d7be8784af7821d1fbb2c7c705b84386b2496dffcbaf9f2943d1e5f00743f214e26839ce64635b9091b43b5747c51f4aaebc0ac27b08f8d5b31921
 DIST tox-4.3.3.gh.tar.gz 298207 BLAKE2B a8de90b5fad31452f3d70e3776a0478e7d7ffbe2a30852d7a1598ee07eac2ca43c291b25bd89c75a16b5266885f67be2d2ac535478905d0a3a276f227ffd62da SHA512 1f357cf52b28cb32d2619b2a3763ca582f39fac53b734cad465d44e28f2321f86387183478a30305bb2ea94140d2a6dcc39092fd0b87bb42ce25d128be58d122
+DIST tox-4.3.4.gh.tar.gz 298487 BLAKE2B d1b36e537cdc8309c550b664e8543ae06329d713fe2267ce2c7082c57c597155b4d1764baedf58c2ce762570a4988bb293ec5e74829e722163dd0d00ed13f558 SHA512 288d7867131009229acfcd3fb78fdc60e0f4de933a64c1a91600cbcee496eb5787e24b43705815705b7d1fe6a4d19f4987571d9a237292d6e7216bd63c235444
diff --git a/dev-python/tox/tox-4.3.4.ebuild b/dev-python/tox/tox-4.3.4.ebuild
new file mode 100644
index 000000000000..287d0a04be39
--- /dev/null
+++ b/dev-python/tox/tox-4.3.4.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv"
+
+RDEPEND="
+	>=dev-python/cachetools-5.2.1[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.8.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.4[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	>=dev-python/virtualenv-20.17.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	# the minimal bounds in tox are entirely meaningless and new packaging
+	# breaks setuptools
+	sed -i -e '/packaging/s:>=[0-9]\+::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	epytest
+}