dev-python/quex: port to python 3.9

Bug: https://bugs.gentoo.org/737374
Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-python/quex/quex-0.71.2.ebuild b/dev-python/quex/quex-0.71.2.ebuild
new file mode 100644
index 000000000000..661695ffa620
--- /dev/null
+++ b/dev-python/quex/quex-0.71.2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_9 )
+
+inherit python-single-r1
+
+DESCRIPTION="Mode Oriented Directly Coded Lexical Analyser Generator"
+HOMEPAGE="http://quex.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.zip"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}"
+BDEPEND="${RDEPEND}
+	app-arch/unzip"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.71.0-gentoo.patch
+)
+
+src_prepare() {
+	default
+	sed -i \
+		-e "s:@PYTHON_SITEDIR@:$(python_get_sitedir):g" \
+		quex/DEFINITIONS.py || die
+	mkdir -p engine/codec_db/unicode || die
+	mv quex/engine/codec_db/database engine/codec_db/ || die
+	mv quex/engine/codec_db/unicode/database engine/codec_db/unicode/ || die
+	mv quex/code_base . || die
+}
+
+src_install() {
+	default
+	insinto /usr/share/quex/
+	doins -r engine
+	doins -r code_base
+
+	python_domodule quex
+	python_newscript quex-exe.py quex
+	doman manpage/quex.1
+	dodoc -r demo
+	insinto /etc/profile.d/
+	doins "${FILESDIR}"/quex.sh
+}