dev-python/geoip-python: add py3.5, fix CFLAGS, EAPI=6

The -fno-strict-aliasing flag is correctly set by the build system
for Python 2 only.

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Closes: https://github.com/gentoo/gentoo/pull/3570

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-python/geoip-python/geoip-python-1.3.2-r1.ebuild b/dev-python/geoip-python/geoip-python-1.3.2-r1.ebuild
new file mode 100644
index 000000000000..72f0ffb8a834
--- /dev/null
+++ b/dev-python/geoip-python/geoip-python-1.3.2-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} pypy pypy3 )
+
+inherit distutils-r1
+
+MY_PN="geoip-api-python"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python bindings for GeoIP"
+HOMEPAGE="https://github.com/maxmind/geoip-api-python"
+SRC_URI="https://github.com/maxmind/${MY_PN}/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-fbsd"
+IUSE="examples test"
+
+RDEPEND=">=dev-libs/geoip-1.4.8"
+DEPEND="
+	${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( README.rst ChangeLog.md )
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}