dev-python/flask-security: Bump to 3.4.5

Bug: https://bugs.gentoo.org/765016
Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/dev-python/flask-security/Manifest b/dev-python/flask-security/Manifest
index 5deb9a83f5a6..03260ea67c0d 100644
--- a/dev-python/flask-security/Manifest
+++ b/dev-python/flask-security/Manifest
@@ -1 +1,2 @@
 DIST flask-security-3.4.4.gh.tar.gz 348525 BLAKE2B 77a851c2549be9ce8612e3b186ad2d83d272b277f286885da491f3f0fe99e8836d145749ae137f1e75625c34b2214270ba4d24f1bfaa514012064dd38f083230 SHA512 1c1a4f079199704d7a2a4e11351cd199e3a790f5d0c7f68b240c299e83b129227fac4ca00caf45401efbf14520c1d65d3b710b85e8f53b495283b94a164f97a2
+DIST flask-security-3.4.5.gh.tar.gz 348928 BLAKE2B 9890227e9775c4a28fc364affb0bf767407463d514f6dc3cd359dd8a026e8325d943a547f294f6363a276f9e7d97336c526dd45f4549c7cfaff2d6ef9ef0316a SHA512 f9ac7f46b2e1ab7dbb44ba925b01e16304e8f8d6d5d56f4e558d07b80dfffa59f04c2597e17c00a7d7ae11be3a97c78ccf8d79993b7451be4a7f75f85bc89f6f
diff --git a/dev-python/flask-security/flask-security-3.4.5.ebuild b/dev-python/flask-security/flask-security-3.4.5.ebuild
new file mode 100644
index 000000000000..9a519a7b4680
--- /dev/null
+++ b/dev-python/flask-security/flask-security-3.4.5.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+inherit distutils-r1
+
+DESCRIPTION="Simple security for Flask apps"
+HOMEPAGE="
+	https://github.com/Flask-Middleware/flask-security/
+	https://pypi.org/project/Flask-Security-Too/"
+SRC_URI="
+	https://github.com/Flask-Middleware/flask-security/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	>=dev-python/flask-1.1.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-babelex-0.9.3[${PYTHON_USEDEP}]
+	>=dev-python/flask-login-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-principal-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-wtf-0.14.2[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.7.2[${PYTHON_USEDEP}]
+	>=dev-python/python-email-validator-1.0.5[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/Babel[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/argon2-cffi-19.1.0[${PYTHON_USEDEP}]
+		>=dev-python/bcrypt-3.1.5[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-2.3.1[${PYTHON_USEDEP}]
+		>=dev-python/flask-mail-0.9.1[${PYTHON_USEDEP}]
+		>=dev-python/flask-mongoengine-0.9.5[${PYTHON_USEDEP}]
+		>=dev-python/flask-sqlalchemy-2.3[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		>=dev-python/mongomock-3.19.0[${PYTHON_USEDEP}]
+		>=dev-python/peewee-3.11.2[${PYTHON_USEDEP}]
+		>=dev-python/phonenumbers-8.11.1[${PYTHON_USEDEP}]
+		>=dev-python/psycopg-2.8.4:2[${PYTHON_USEDEP}]
+		>=dev-python/pymysql-0.9.3[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.2[${PYTHON_USEDEP}]
+		>=dev-python/zxcvbn-4.4.28[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/pony-0.7.11[${PYTHON_USEDEP}]
+		' python3_{6,7})
+	)"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.4.3-optional-deps.patch
+)
+
+src_prepare() {
+	sed -i -e '/setup_requires/d' setup.py || die
+	sed -e 's@--cov flask_security@-p no:httpbin@' \
+		-e 's:--cov-report term-missing::' \
+		-e 's:--black::' \
+		-e 's:--flake8::' \
+		-e 's:--cache-clear::' \
+		-i pytest.ini || die
+	distutils-r1_src_prepare
+}
+
+python_configure_all() {
+	esetup.py compile_catalog
+}