dev-perl/SOAP-Lite: Bump to version 1.260.0

- EAPI6
- Add USE="examples"
- Cleanup author tests
- Remove bogus CPAN remote-id's

Upstream:
- Test fixes
- Use '/usr/bin/env perl' ( ugh? )
- Correct the saop namespace declaration when calling services defined
  in WSDL
- Fix Unicode data encoding
- Remove is_utf8 check
- Remove use of UNIVERSAL::isa
- Doc fixes

Package-Manager: Portage-2.3.18, Repoman-2.3.6

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-perl/SOAP-Lite/SOAP-Lite-1.260.0.ebuild b/dev-perl/SOAP-Lite/SOAP-Lite-1.260.0.ebuild
new file mode 100644
index 000000000000..bd48e266b0b5
--- /dev/null
+++ b/dev-perl/SOAP-Lite/SOAP-Lite-1.260.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DIST_AUTHOR=PHRED
+DIST_VERSION=1.26
+DIST_EXAMPLES=( "examples/*" )
+inherit perl-module eutils
+
+DESCRIPTION="Lightweight interface to the SOAP protocol both on client and server side"
+
+IUSE="ssl test xmpp"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+
+myconf="${myconf} --noprompt"
+
+RDEPEND="
+	dev-perl/Class-Inspector
+	>=dev-perl/IO-SessionData-1.30.0
+	dev-perl/libwww-perl
+	virtual/perl-MIME-Base64
+	virtual/perl-Scalar-List-Utils
+	dev-perl/Task-Weaken
+	dev-perl/URI
+	>=dev-perl/XML-Parser-2.230.0
+	dev-perl/MIME-tools
+	ssl? (
+		dev-perl/IO-Socket-SSL
+		dev-perl/LWP-Protocol-https
+		dev-perl/Crypt-SSLeay
+	)
+	xmpp? ( dev-perl/Net-Jabber )
+"
+DEPEND="${RDEPEND}
+	virtual/perl-ExtUtils-MakeMaker
+	test? (
+		virtual/perl-IO
+		virtual/perl-Test-Simple
+		dev-perl/Test-Warn
+		>=dev-perl/XML-Parser-Lite-0.715.0
+	)
+"
+PERL_RM_FILES=(
+	"t/author-pod-syntax.t"
+	"t/release-kwalitee.t"
+)
+src_test() {
+	has_version '>=www-apache/mod_perl-2' && export MOD_PERL_API_VERSION=2
+	perl-module_src_test
+}