dev-perl/Image-Scale: Bump to version 0.130.0

Upstream:
- Skip JPEG binary comparison tests
- Properly work with jpeg-turbo
- Support glflib 4.1.x
- save_jpeg()/save_png() properly stringify path objects

Package-Manager: Portage-2.3.8, Repoman-2.3.3

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-perl/Image-Scale/Image-Scale-0.130.0.ebuild b/dev-perl/Image-Scale/Image-Scale-0.130.0.ebuild
new file mode 100644
index 000000000000..ac3988afea1b
--- /dev/null
+++ b/dev-perl/Image-Scale/Image-Scale-0.130.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DIST_AUTHOR=AGRUNDMA
+DIST_VERSION=0.13
+inherit perl-module
+
+DESCRIPTION="Fast, high-quality fixed-point image resizing"
+
+LICENSE="|| ( GPL-2 GPL-3 )" # GPL2+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gif jpeg +png test"
+
+REQUIRED_USE="|| ( jpeg png )"
+
+RDEPEND="
+	png? (
+		media-libs/libpng:0
+	)
+	jpeg? (
+		virtual/jpeg:0
+	)
+	gif? (
+		media-libs/giflib
+	)
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-perl/Test-NoWarnings
+	)
+	virtual/perl-ExtUtils-MakeMaker
+"
+# https://rt.cpan.org/Ticket/Display.html?id=112217
+DIST_TEST="do"
+PATCHES=(
+	"${FILESDIR}"/0.80.0-disable_autodetect.patch
+)
+src_prepare() {
+	use test && perl_rm_files "t/04critic.t" "t/02pod.t" "t/03podcoverage.t"
+	perl-module_src_prepare
+}
+src_configure() {
+	local myconf
+	for useflag in png jpeg gif; do
+		myconf+=( $(usex $useflag "" --disable-${useflag}) )
+	done
+	perl-module_src_configure
+}