dev-cpp/catch: patch for glibc-2.34

Kind of cheesy patch but it is what it is, Catch1 is dead anyway.

Closes: https://bugs.gentoo.org/803962
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-cpp/catch/catch-1.12.2-r1.ebuild b/dev-cpp/catch/catch-1.12.2-r1.ebuild
new file mode 100644
index 000000000000..9120c50ed593
--- /dev/null
+++ b/dev-cpp/catch/catch-1.12.2-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/catchorg/Catch2.git"
+	EGIT_BRANCH="Catch1.x"
+else
+	MY_P=${PN^}-${PV}
+	SRC_URI="https://github.com/catchorg/Catch2/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+	S="${WORKDIR}/${PN^}2-${PV}"
+fi
+
+DESCRIPTION="Modern C++ header-only framework for unit-tests"
+HOMEPAGE="https://github.com/catchorg/Catch2"
+
+LICENSE="Boost-1.0"
+SLOT="1"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="!<dev-cpp/catch-1.12.2:0"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.12.2-glibc-2.34-sigstksz.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DNO_SELFTEST=$(usex !test)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	dodoc -r docs/.
+}