app-misc/task: vbump 2.6.2

Signed-off-by: David Denoncin <ddenoncin@gmail.com>
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

1 files changed, 70 insertions, 0 deletions

diff --git a/app-misc/task/task-2.6.2.ebuild b/app-misc/task/task-2.6.2.ebuild
new file mode 100644
index 000000000000..db350fe67469
--- /dev/null
+++ b/app-misc/task/task-2.6.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+inherit bash-completion-r1 cmake
+
+DESCRIPTION="Taskwarrior is a command-line todo list manager"
+HOMEPAGE="https://taskwarrior.org/"
+SRC_URI="https://github.com/GothenburgBitFactory/taskwarrior/releases/download/v${PV}/${P}.tar.gz
+	https://github.com/GothenburgBitFactory/taskwarrior/releases/download/v${PV}/tests-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~x64-macos"
+IUSE="+sync"
+
+DEPEND="
+	sync? ( net-libs/gnutls )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# move test directory into source directory
+	mv "${WORKDIR}"/test "${WORKDIR}"/${P} || die
+
+	cmake_src_prepare
+
+	# don't automatically install scripts
+	sed -i '/scripts/d' CMakeLists.txt || die
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DENABLE_SYNC=$(usex sync)
+		-DTASK_DOCDIR=share/doc/${PF}
+		-DTASK_RCDIR=share/${PN}/rc
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${WORKDIR}"/"${P}"_build || die
+
+	emake test
+}
+
+src_install() {
+	cmake_src_install
+
+	newbashcomp scripts/bash/task.sh task
+
+	# vim syntax
+	rm scripts/vim/README || die
+	insinto /usr/share/vim/vimfiles
+	doins -r scripts/vim/*
+
+	# zsh-completions
+	insinto /usr/share/zsh/site-functions
+	doins scripts/zsh/*
+
+	# fish-completions
+	insinto /usr/share/fish/vendor_completions.d
+	doins scripts/fish/*
+
+	exeinto "/usr/share/${PN}/scripts"
+	doexe scripts/add-ons/*
+}