app-emulation/spice: add 0.15.2

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 136 insertions, 46 deletions

diff --git a/app-emulation/spice/Manifest b/app-emulation/spice/Manifest
index cc57e343819a..32f53c4a8b1e 100644
--- a/app-emulation/spice/Manifest
+++ b/app-emulation/spice/Manifest
@@ -1,3 +1,4 @@
 DIST spice-0.15.0-pthread-c5fe3df1.patch.bz2 7605 BLAKE2B 86b8094a22a02080db038ef98972bf09f391d5344fee8df2aa7d2def0b50a581353cb0e3dd97f99bbd58b88a13ceac4b54be8086a9f4274f38d132b27b62e84d SHA512 5075bd260b33c2dad8c3ce641372383871f7d69190a4f4697bd5e12af1bf5429310c592961de001d36c19a9cdd91143b8d6e8be0e08b3850b9700c2aef2ddd78
 DIST spice-0.15.0.tar.bz2 1537970 BLAKE2B 98e8f55de81a86c6370e4a74c0fd90db78a9a8e8e3af536bccd6a2a75185194ac7b87521163090c4312e392d2ee10036c0283171c7796aea630e1307128a2d55 SHA512 0a776d191c395ce1f7ebbbac47956a00a2765327d3127aeca6e232bd56fd4ccd28750ae1599eb6eb2909ac909cda517d5511faa631166db16b8b75bd4e7b86d9
 DIST spice-0.15.1.tar.bz2 1623290 BLAKE2B 19ddb3cac91be07a4a358ed89a5e4d1a5c406a9831b8c8a518764055354ecf6e09d129ae03ba65d876669da72f2cbf0c307261564097f60951711e9852eebb69 SHA512 362ab2f0b483911830693834515e1d331a6b929c5c63fd4522e843c42bbb7d8a52510d60f5f17d175dd2617c9621630f6a81f3ff7dce11dc28e6fb135e60fa86
+DIST spice-0.15.2.tar.bz2 1663326 BLAKE2B 00f5393ac409590b8fe0203251b811a4fe6dca16e644a30dd8165d57ff28cbef3b2f9c2a92ff7d2f6c8092bbef4f89a4e85ef9228cc8c03b0a163ffa3afaf9f6 SHA512 c8f273b9e97ef38a03b331f7d32c5f0a09d540523fe626568c845152cbd22273a92b3a08bc13fa2e061b913ad16ceb7cbddf142655cd9cdcd8eb5f646fa6aa26
diff --git a/app-emulation/spice/spice-0.15.2.ebuild b/app-emulation/spice/spice-0.15.2.ebuild
new file mode 100644
index 000000000000..b1b52a3283e5
--- /dev/null
+++ b/app-emulation/spice/spice-0.15.2.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+inherit meson python-any-r1 readme.gentoo-r1 xdg-utils
+
+DESCRIPTION="SPICE server"
+HOMEPAGE="https://www.spice-space.org/"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/spice/spice.git"
+	inherit git-r3
+
+	DEPEND="~app-emulation/spice-protocol-9999"
+else
+	SRC_URI="https://www.spice-space.org/download/releases/spice-server/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="gstreamer lz4 sasl smartcard static-libs test"
+RESTRICT="!test? ( test )"
+
+# The libspice-server only uses the headers of libcacard
+RDEPEND="
+	dev-lang/orc[static-libs(+)?]
+	>=dev-libs/glib-2.38:2[static-libs(+)?]
+	dev-libs/openssl:0=[static-libs(+)?]
+	media-libs/opus[static-libs(+)?]
+	media-libs/libjpeg-turbo:0=[static-libs(+)?]
+	sys-libs/zlib[static-libs(+)?]
+	>=x11-libs/pixman-0.17.7[static-libs(+)?]
+	lz4? ( app-arch/lz4:0=[static-libs(+)?] )
+	smartcard? ( >=app-emulation/libcacard-2.5.1 )
+	sasl? ( dev-libs/cyrus-sasl[static-libs(+)?] )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+"
+DEPEND+="
+	${RDEPEND}
+	>=app-emulation/spice-protocol-0.14.3
+	smartcard? ( app-emulation/qemu[smartcard] )
+	test? ( net-libs/glib-networking )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	$(python_gen_any_dep '
+		>=dev-python/pyparsing-1.5.6-r2[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+	')
+"
+
+python_check_deps() {
+	python_has_version -b ">=dev-python/pyparsing-1.5.6-r2[${PYTHON_USEDEP}]"
+	python_has_version -b "dev-python/six[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# Prevent sandbox violations, bug #586560
+	# https://bugzilla.gnome.org/show_bug.cgi?id=744134
+	# https://bugzilla.gnome.org/show_bug.cgi?id=744135
+	use gstreamer && addpredict /dev
+
+	xdg_environment_reset
+
+	local emesonargs=(
+		-Ddefault_library=$(usex static-libs both shared)
+		-Dgstreamer=$(usex gstreamer 1.0 no)
+		-Dopus=enabled
+		-Dmanual=false
+		$(meson_use lz4)
+		$(meson_use sasl)
+		$(meson_feature smartcard)
+		$(meson_use test tests)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
diff --git a/app-emulation/spice/spice-9999.ebuild b/app-emulation/spice/spice-9999.ebuild
index 8b1ec904e164..b1b52a3283e5 100644
--- a/app-emulation/spice/spice-9999.ebuild
+++ b/app-emulation/spice/spice-9999.ebuild
@@ -1,60 +1,63 @@
 # Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-PYTHON_COMPAT=( python3_{9..11} )
-inherit git-r3 meson python-any-r1 readme.gentoo-r1 xdg-utils
+PYTHON_COMPAT=( python3_{10..11} )
+inherit meson python-any-r1 readme.gentoo-r1 xdg-utils
 
 DESCRIPTION="SPICE server"
 HOMEPAGE="https://www.spice-space.org/"
-SRC_URI=""
-EGIT_REPO_URI="https://anongit.freedesktop.org/git/spice/spice.git"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/spice/spice.git"
+	inherit git-r3
+
+	DEPEND="~app-emulation/spice-protocol-9999"
+else
+	SRC_URI="https://www.spice-space.org/download/releases/spice-server/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS=""
-IUSE="gstreamer lz4 opus sasl smartcard static-libs test"
-
+IUSE="gstreamer lz4 sasl smartcard static-libs test"
 RESTRICT="!test? ( test )"
 
-# the libspice-server only uses the headers of libcacard
+# The libspice-server only uses the headers of libcacard
 RDEPEND="
-	dev-lang/orc
-	>=dev-libs/glib-2.38:2
-	sys-libs/zlib
-	virtual/jpeg:0=
-	>=x11-libs/pixman-0.17.7
-	dev-libs/openssl:0=
-	lz4? ( app-arch/lz4:0= )
-	opus? ( media-libs/opus )
+	dev-lang/orc[static-libs(+)?]
+	>=dev-libs/glib-2.38:2[static-libs(+)?]
+	dev-libs/openssl:0=[static-libs(+)?]
+	media-libs/opus[static-libs(+)?]
+	media-libs/libjpeg-turbo:0=[static-libs(+)?]
+	sys-libs/zlib[static-libs(+)?]
+	>=x11-libs/pixman-0.17.7[static-libs(+)?]
+	lz4? ( app-arch/lz4:0=[static-libs(+)?] )
 	smartcard? ( >=app-emulation/libcacard-2.5.1 )
-	sasl? ( dev-libs/cyrus-sasl )
+	sasl? ( dev-libs/cyrus-sasl[static-libs(+)?] )
 	gstreamer? (
 		media-libs/gstreamer:1.0
 		media-libs/gst-plugins-base:1.0
-	)"
-DEPEND="${RDEPEND}
-	~app-emulation/spice-protocol-9999
+	)
+"
+DEPEND+="
+	${RDEPEND}
+	>=app-emulation/spice-protocol-0.14.3
 	smartcard? ( app-emulation/qemu[smartcard] )
-	test? ( net-libs/glib-networking )"
-BDEPEND="${PYTHON_DEPS}
-	sys-devel/autoconf-archive
+	test? ( net-libs/glib-networking )
+"
+BDEPEND="
+	${PYTHON_DEPS}
 	virtual/pkgconfig
 	$(python_gen_any_dep '
 		>=dev-python/pyparsing-1.5.6-r2[${PYTHON_USEDEP}]
 		dev-python/six[${PYTHON_USEDEP}]
-	')"
-
-DOCS=(
-	AUTHORS
-	CHANGELOG.md
-	README
-)
+	')
+"
 
 python_check_deps() {
-	has_version -b ">=dev-python/pyparsing-1.5.6-r2[${PYTHON_USEDEP}]"
-	has_version -b "dev-python/six[${PYTHON_USEDEP}]"
+	python_has_version -b ">=dev-python/pyparsing-1.5.6-r2[${PYTHON_USEDEP}]"
+	python_has_version -b "dev-python/six[${PYTHON_USEDEP}]"
 }
 
 pkg_setup() {
@@ -72,29 +75,19 @@ src_configure() {
 	local emesonargs=(
 		-Ddefault_library=$(usex static-libs both shared)
 		-Dgstreamer=$(usex gstreamer 1.0 no)
+		-Dopus=enabled
+		-Dmanual=false
 		$(meson_use lz4)
 		$(meson_use sasl)
-		$(meson_feature opus)
 		$(meson_feature smartcard)
 		$(meson_use test tests)
-		-Dmanual=false
-		-Dtests=false
 	)
-	meson_src_configure
-}
 
-src_compile() {
-	# Prevent sandbox violations, bug #586560
-	# https://bugzilla.gnome.org/show_bug.cgi?id=744134
-	# https://bugzilla.gnome.org/show_bug.cgi?id=744135
-	use gstreamer && addpredict /dev
-
-	meson_src_compile
+	meson_src_configure
 }
 
 src_install() {
 	meson_src_install
-	einstalldocs
 	readme.gentoo_create_doc
 }