app-editors/pluma: 1.12.x vbump, add gtk3 support, import from project repo

Package-Manager: portage-2.3.0

3 files changed, 96 insertions, 0 deletions

diff --git a/app-editors/pluma/Manifest b/app-editors/pluma/Manifest
index f479f56961cc..8313b6334b71 100644
--- a/app-editors/pluma/Manifest
+++ b/app-editors/pluma/Manifest
@@ -1 +1,2 @@
 DIST pluma-1.10.2.tar.xz 3442784 SHA256 c0614334dc99e5dde73cbda6cb561cb1a5dc3e3269d74a4134095f9abf73c89a SHA512 bb41e18419fee07c812ebebb9802a77c325d876d05d37e1e9229e4228b0939ef8c80b1377922b94f02a7b7d02fbff62d4e4959815bd94d5b0da3bfa1afebae60 WHIRLPOOL 2edf0078267887af4349537f3c36f7971ab9aad66219e02fe41e47cacc9b91408e668c2294a8c6d6a497b68017b704fe7c7c17fe7ff22030b4c36e330b0def5a
+DIST pluma-1.12.2.tar.xz 3397280 SHA256 eb74988a9fa9892f883b2ccdc9cf217478576815bcb02662d2e3cf2ae39ef870 SHA512 db2878161903868703514531ba214fc34dad1789885f18756e9192d6ba17950c8be03141ada72f8c386b515d8b0f9d58a0ee94a33fe3ffe00f360ea667c2b275 WHIRLPOOL 30e45dc3e399e77403d23ebe1c8fb98592f3a408de3bd5ee724e621168b26116de0c520348dd74929e360a251b8d727ef9967746b14732fc6e03d63ffb3091c4
diff --git a/app-editors/pluma/metadata.xml b/app-editors/pluma/metadata.xml
index 898165dfa5bc..a12d1e4e54ba 100644
--- a/app-editors/pluma/metadata.xml
+++ b/app-editors/pluma/metadata.xml
@@ -5,6 +5,9 @@
         <email>mate@gentoo.org</email>
         <name>Gentoo MATE Desktop</name>
     </maintainer>
+	<use>
+		<flag name="gtk3">Build with GTK+3 instead of GTK+2</flag>
+	</use>
     <upstream>
         <remote-id type="github">mate-desktop/pluma</remote-id>
     </upstream>
diff --git a/app-editors/pluma/pluma-1.12.2-r1.ebuild b/app-editors/pluma/pluma-1.12.2-r1.ebuild
new file mode 100644
index 000000000000..1e6303c734d7
--- /dev/null
+++ b/app-editors/pluma/pluma-1.12.2-r1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MATE_LA_PUNT="yes"
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit mate multilib python-single-r1 virtualx
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+DESCRIPTION="Pluma text editor for the MATE desktop"
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="gtk3 python spell"
+
+REQUIRED_USE="
+	gtk3? ( !python )
+	python? ( ${PYTHON_REQUIRED_USE} )"
+
+# Tests require gvfs sftp fs mounted and schema's installed. Disable tests.
+# https://github.com/mate-desktop/mate-text-editor/issues/33
+RESTRICT="test"
+
+RDEPEND="app-text/rarian:0
+	dev-libs/atk:0
+	>=dev-libs/glib-2.36:2
+	>=dev-libs/libxml2-2.5:2
+	>=mate-base/mate-desktop-1.9[gtk3(-)=]
+	x11-libs/cairo:0
+	x11-libs/gdk-pixbuf:2
+	x11-libs/libICE:0
+	x11-libs/libX11:0
+	>=x11-libs/libSM-1.0
+	x11-libs/pango:0
+	virtual/libintl:0
+	!gtk3? (
+		>=x11-libs/gtk+-2.24:2
+		>=x11-libs/gtksourceview-2.9.7:2.0
+	)
+	gtk3? (
+		>=x11-libs/gtk+-3.0:3
+		>=x11-libs/gtksourceview-2.9.7:3.0
+	)
+	spell? (
+		>=app-text/enchant-1.2:0
+		>=app-text/iso-codes-0.35:0
+	)
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/pygobject-2.15.4:2[${PYTHON_USEDEP}]
+		>=dev-python/pygtk-2.12:2[${PYTHON_USEDEP}]
+		>=dev-python/pygtksourceview-2.9.2:2
+	)
+	!!app-editors/mate-text-editor"
+
+DEPEND="${RDEPEND}
+	~app-text/docbook-xml-dtd-4.1.2
+	>=app-text/scrollkeeper-dtd-1:1.0
+	app-text/yelp-tools:0
+	dev-util/gtk-doc
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.50.1:*
+	>=sys-devel/libtool-2.2.6:2
+	>=sys-devel/gettext-0.17:*
+	virtual/pkgconfig:*"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	mate_src_configure \
+		--with-gtk=$(usex gtk3 3.0 2.0) \
+		$(use_enable python) \
+		$(use_enable spell)
+}
+
+src_test() {
+	# FIXME: This should be handled at eclass level.
+	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+
+	unset DBUS_SESSION_BUS_ADDRESS
+
+	GSETTINGS_SCHEMA_DIR="${S}/data" Xemake check
+}