app-admin/pass: version bump

Package-Manager: Portage-2.3.3, Repoman-2.3.1

4 files changed, 89 insertions, 8 deletions

diff --git a/app-admin/pass/Manifest b/app-admin/pass/Manifest
index 7a29467b2dd8..4935823580c6 100644
--- a/app-admin/pass/Manifest
+++ b/app-admin/pass/Manifest
@@ -1 +1,2 @@
 DIST password-store-1.6.5.tar.xz 54576 SHA256 337a39767e6a8e69b2bcc549f27ff3915efacea57e5334c6068fcb72331d7315 SHA512 e28503b63c6d18a2f45f4a732fdec0380c2ac15e1778136ec5e7ac568662b09183d3ad4fd36ca7e87cfe74540f916cb6365695bdf665a39da4cbe86c4bde7a78 WHIRLPOOL da5a5652d6fcea4f571135072f205cc7ad1aecb927478fde7979051557df958e9c51c47363c12f213deafbd7572eefe0f204acda7e430548e365f0e7fdc0c94f
+DIST password-store-1.7.tar.xz 62372 SHA256 161ac3bd3c452a97f134aa7aa4668fe3f2401c839fd23c10e16b8c0ae4e15500 SHA512 f31fd067f9c6134eac7bb5039df6de3d6fe25c9fcd16d27a0cba159bd7fa9361193081a1fff2000cba1943edbb324e645c6399d4f4aa9f441dd9c67696462a50 WHIRLPOOL d9630fd9fb17e5a84f13627059357ba412981e258c31c33b81ce147b315ffdeda43a651a1212beb060ceb03b770f28d7b8364c6e4eb670a901ff05a128560edb
diff --git a/app-admin/pass/pass-1.6.5.ebuild b/app-admin/pass/pass-1.6.5.ebuild
index 0178ee360bd0..6192070f19df 100644
--- a/app-admin/pass/pass-1.6.5.ebuild
+++ b/app-admin/pass/pass-1.6.5.ebuild
@@ -7,8 +7,8 @@ EAPI=5
 inherit bash-completion-r1 elisp-common
 
 DESCRIPTION="Stores, retrieves, generates, and synchronizes passwords securely"
-HOMEPAGE="http://www.passwordstore.org/"
-SRC_URI="http://git.zx2c4.com/password-store/snapshot/password-store-${PV}.tar.xz"
+HOMEPAGE="https://www.passwordstore.org/"
+SRC_URI="https://git.zx2c4.com/password-store/snapshot/password-store-${PV}.tar.xz"
 
 SLOT="0"
 LICENSE="GPL-2"
diff --git a/app-admin/pass/pass-1.7.ebuild b/app-admin/pass/pass-1.7.ebuild
new file mode 100644
index 000000000000..0fd3049bdc35
--- /dev/null
+++ b/app-admin/pass/pass-1.7.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit bash-completion-r1 elisp-common
+
+DESCRIPTION="Stores, retrieves, generates, and synchronizes passwords securely"
+HOMEPAGE="https://www.passwordstore.org/"
+SRC_URI="https://git.zx2c4.com/password-store/snapshot/password-store-${PV}.tar.xz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86 ~x86-macos"
+IUSE="+git X zsh-completion fish-completion emacs dmenu importers elibc_Darwin"
+
+RDEPEND="
+	app-crypt/gnupg
+	media-gfx/qrencode
+	>=app-text/tree-1.7.0
+	git? ( dev-vcs/git )
+	X? ( x11-misc/xclip )
+	elibc_Darwin? ( app-misc/getopt )
+	zsh-completion? ( app-shells/gentoo-zsh-completions )
+	fish-completion? ( app-shells/fish )
+	dmenu? ( x11-misc/dmenu x11-misc/xdotool )
+	emacs? ( virtual/emacs )
+"
+
+S="${WORKDIR}/password-store-${PV}"
+
+src_prepare() {
+	use elibc_Darwin || return
+	# use coreutils'
+	sed -i -e 's/openssl base64/base64/g' src/platform/darwin.sh || die
+	# host getopt isn't cool, and we aren't brew (rip out brew reference)
+	sed -i -e '/^GETOPT=/s/=.*$/=getopt-long/' src/platform/darwin.sh || die
+	# make sure we can find "mount"
+	sed -i -e 's:mount -t:/sbin/mount -t:' src/platform/darwin.sh || die
+}
+
+src_compile() {
+	:;
+}
+
+src_install() {
+	emake install \
+		DESTDIR="${D}" \
+		PREFIX="${EPREFIX}/usr" \
+		BASHCOMPDIR="$(get_bashcompdir)" \
+		WITH_BASHCOMP=yes \
+		WITH_ZSHCOMP=$(usex zsh-completion) \
+		WITH_FISHCOMP=$(usex fish-completion)
+	use dmenu && dobin contrib/dmenu/passmenu
+	if use emacs; then
+		elisp-install ${PN} contrib/emacs/*.el
+		elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
+	fi
+	if use importers; then
+		exeinto /usr/share/${PN}/importers
+		doexe contrib/importers/*
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+	if use importers; then
+		einfo "To import passwords from other password managers, you may use the"
+		einfo "various importer scripts found in:"
+		einfo "    ${ROOT}usr/share/${PN}/importers/"
+	fi
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
diff --git a/app-admin/pass/pass-9999.ebuild b/app-admin/pass/pass-9999.ebuild
index cd67642663d3..a3f305b93374 100644
--- a/app-admin/pass/pass-9999.ebuild
+++ b/app-admin/pass/pass-9999.ebuild
@@ -7,7 +7,7 @@ EAPI=5
 inherit bash-completion-r1 git-2 elisp-common
 
 DESCRIPTION="Stores, retrieves, generates, and synchronizes passwords securely"
-HOMEPAGE="http://www.passwordstore.org/"
+HOMEPAGE="https://www.passwordstore.org/"
 EGIT_REPO_URI="https://git.zx2c4.com/password-store"
 
 SLOT="0"
@@ -17,7 +17,7 @@ IUSE="+git X zsh-completion fish-completion emacs dmenu importers elibc_Darwin"
 
 RDEPEND="
 	app-crypt/gnupg
-	app-admin/pwgen
+	media-gfx/qrencode
 	>=app-text/tree-1.7.0
 	git? ( dev-vcs/git )
 	X? ( x11-misc/xclip )
@@ -45,11 +45,14 @@ src_compile() {
 }
 
 src_install() {
-	use zsh-completion && export FORCE_ZSHCOMP=1
-	use fish-completion && export FORCE_FISHCOMP=1
-	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+	emake install \
+		DESTDIR="${D}" \
+		PREFIX="${EPREFIX}/usr" \
+		BASHCOMPDIR="$(get_bashcompdir)" \
+		WITH_BASHCOMP=yes \
+		WITH_ZSHCOMP=$(usex zsh-completion) \
+		WITH_FISHCOMP=$(usex fish-completion)
 	use dmenu && dobin contrib/dmenu/passmenu
-	newbashcomp src/completion/pass.bash-completion pass
 	if use emacs; then
 		elisp-install ${PN} contrib/emacs/*.el
 		elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"