dev-lisp/ecls: Fix QA, port to EAPI 7

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Closes: https://bugs.gentoo.org/727618
Signed-off-by: François René Pierre Bissey <frp.bissey@gmail.com>
Signed-off-by: Ulrich Müller <ulm@gentoo.org>

2 files changed, 102 insertions, 0 deletions

diff --git a/dev-lisp/ecls/ecls-21.2.1-r4.ebuild b/dev-lisp/ecls/ecls-21.2.1-r4.ebuild
new file mode 100644
index 000000000000..9bec3c30a5ef
--- /dev/null
+++ b/dev-lisp/ecls/ecls-21.2.1-r4.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit readme.gentoo-r1
+
+# test phase only works if ecls already installed #516876
+RESTRICT="test"
+
+MY_P=ecl-${PV}
+
+DESCRIPTION="ECL is an embeddable Common Lisp implementation"
+HOMEPAGE="https://common-lisp.net/project/ecl/"
+SRC_URI="https://common-lisp.net/project/ecl/static/files/release/${MY_P}.tgz"
+
+LICENSE="BSD-2 LGPL-2.1+"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
+IUSE="cxx debug emacs gengc precisegc cpu_flags_x86_sse +threads +unicode X"
+
+CDEPEND="dev-libs/gmp:0=
+		dev-libs/libffi:=
+		dev-libs/libatomic_ops
+		>=dev-libs/boehm-gc-7.1[threads?]
+		>=dev-lisp/asdf-2.33-r3:="
+DEPEND="${CDEPEND}
+		app-text/texi2html
+		emacs? ( >=app-editors/emacs-23.1:* >=app-eselect/eselect-emacs-1.12 )"
+RDEPEND="${CDEPEND}"
+
+S="${WORKDIR}"/${MY_P}
+
+DOCS=( README.md CHANGELOG )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-16.1.3-headers-gentoo.patch"
+	"${FILESDIR}/${PN}-16.1.3-build.patch"
+)
+
+src_prepare() {
+	default
+	cp "${EPREFIX}"/usr/share/common-lisp/source/asdf/build/asdf.lisp contrib/asdf/ || die
+}
+
+src_configure() {
+	econf \
+		--enable-gmp=system \
+		--enable-boehm=system \
+		--with-dffi \
+		--enable-libatomic=system \
+		--with-defsystem \
+		$(use_with cxx) \
+		$(use_enable gengc) \
+		$(use_enable precisegc) \
+		$(use_with debug debug-cflags) \
+		$(use_with cpu_flags_x86_sse sse) \
+		$(use_enable threads) \
+		$(use_enable unicode) \
+		$(use_with X x)
+}
+
+src_compile() {
+	if use emacs; then
+		local ETAGS=$(eselect --brief etags list | sed -ne '/emacs/{p;q}')
+		[[ -n ${ETAGS} ]] || die "No etags implementation found"
+		pushd build > /dev/null || die
+		emake ETAGS=${ETAGS} TAGS
+		popd > /dev/null || die
+	else
+		touch build/TAGS
+	fi
+
+	emake
+}
+
+src_install() {
+	default
+
+	readme.gentoo_create_doc
+	pushd build/doc > /dev/null || die
+	newman ecl.man ecl.1
+	newman ecl-config.man ecl-config.1
+	popd > /dev/null || die
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
diff --git a/dev-lisp/ecls/files/README.gentoo b/dev-lisp/ecls/files/README.gentoo
new file mode 100644
index 000000000000..c95b6cb75167
--- /dev/null
+++ b/dev-lisp/ecls/files/README.gentoo
@@ -0,0 +1,13 @@
+-*- outline -*-
+
+Gentoo GNU/Linux specific notes for ECL
+---------------------------------------
+
+  * The Gentoo port includes a patch to ECL's installed header file (ech.h) so
+    that TRUE and FALSE are not redefined if they're already included from
+    elsewhere. This makes it easier to use ECL with other software which defines
+    those C preprocesser symbols (eg. glib-2.0).
+
+If you encounter any problems or have suggestions, use https://bugs.gentoo.org/.
+Please don't bother the upstream authors unless you are absolutely certain it is
+not Gentoo-related.