sys-cluster/charliecloud: Version bump to 0.18.

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Oliver Freyermuth <o.freyermuth@googlemail.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

3 files changed, 82 insertions, 1 deletions

diff --git a/sys-cluster/charliecloud/Manifest b/sys-cluster/charliecloud/Manifest
index 3b195292bc24..b65558546280 100644
--- a/sys-cluster/charliecloud/Manifest
+++ b/sys-cluster/charliecloud/Manifest
@@ -1,2 +1,3 @@
 DIST charliecloud-0.15.tar.gz 346718 BLAKE2B a3710814864904c5db282d092f64faf9a11aeea016c788ee4be62f11257b5b5200d0c1887150b93f18446034d7919df933d3badcf33907a81c0b33e65a5e9f78 SHA512 70f6c9a18f613d05396eda5d41044ec699cf6366ae1bf43839275e62ac317231bb1c3278469040faa03af007260d84e2d718c0fb3fb45e6ace8fb733c6275a84
 DIST charliecloud-0.16.tar.gz 356118 BLAKE2B 72e7640feb23fbc55c515fd841cf90562b7800a83673b6a786c8162229b6714ed6a98d3c5066e42ce75a58935e085e86e42ae927cd5f14e6e54ffe6e9863629e SHA512 bf37b5ea2d139635f3207475497bd90595ce625ce9ad05eef5fcd19ec3252e4843eba2bd457587cd9c4ab860aa1e40ec01ac5cd073414bb5a4f89b5c4488bceb
+DIST charliecloud-0.18.tar.gz 366210 BLAKE2B 0da9542cccc39ff6f3ce97532e8576b8eb91c9d7f104fb31c1fe47ca88b3eb0150370fe7585c96a3f9ac3eee28e853866cf9a2c4bfc03b6dd1961d3731ae5439 SHA512 0b23db2348fb1fd491e450fa8684c47dae5acbbdac10fc3b12b5019e1db5f7024d259b43d082e0a4a202b5e79e042e408460d4b52f1e634eff3d4a7f4e68c50b
diff --git a/sys-cluster/charliecloud/charliecloud-0.18.ebuild b/sys-cluster/charliecloud/charliecloud-0.18.ebuild
new file mode 100644
index 000000000000..b35d7def4f93
--- /dev/null
+++ b/sys-cluster/charliecloud/charliecloud-0.18.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit autotools optfeature python-single-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/hpc/${PN}.git"
+	S="${WORKDIR}/${P}"
+else
+	SRC_URI="https://github.com/hpc/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~x86-linux"
+fi
+
+DESCRIPTION="Lightweight user-defined software stacks for high-performance computing"
+HOMEPAGE="https://hpc.github.io/charliecloud/"
+
+SLOT="0"
+LICENSE="Apache-2.0"
+IUSE="ch-grow doc examples +pv +squashfs squashfuse"
+
+# Extensive test suite exists, but downloads container images
+# directly and via Docker and installs packages inside using apt/yum.
+# Additionally, clashes with portage namespacing and sandbox.
+RESTRICT="test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	pv? ( sys-apps/pv )
+	squashfs? ( sys-fs/squashfs-tools )
+	squashfuse? ( sys-fs/squashfuse )"
+DEPEND="
+	ch-grow? (
+		$(python_gen_cond_dep '
+			dev-python/lark-parser[${PYTHON_MULTI_USEDEP}]
+			dev-python/requests[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+	doc? (
+		$(python_gen_cond_dep '
+			dev-python/sphinx[${PYTHON_MULTI_USEDEP}]
+			dev-python/sphinx_rtd_theme[${PYTHON_MULTI_USEDEP}]
+		')
+		net-misc/rsync
+	)"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local econf_args=()
+	econf_args+=(
+		$(use_enable doc html)
+		$(use_enable ch-grow)
+		# Libdir is used as a libexec-style destination.
+		--libdir="${EPREFIX}"/usr/lib
+		# Attempts to call python-exec directly otherwise.
+		--with-sphinx-python=${PYTHON}
+		# This disables -Werror, see also: https://github.com/hpc/charliecloud/pull/808
+		--enable-buggy-build
+	)
+	econf "${econf_args[@]}"
+}
+
+pkg_postinst() {
+	elog "Various builders are supported, as alternative "
+	elog "to the internal ch-grow. The following packages "
+	elog "can be installed to get the corresponding support."
+
+	optfeature "Building with Buildah" app-emulation/buildah
+	optfeature "Building with Docker" app-emulation/docker
+}
diff --git a/sys-cluster/charliecloud/charliecloud-9999.ebuild b/sys-cluster/charliecloud/charliecloud-9999.ebuild
index d1d834d0655c..b35d7def4f93 100644
--- a/sys-cluster/charliecloud/charliecloud-9999.ebuild
+++ b/sys-cluster/charliecloud/charliecloud-9999.ebuild
@@ -51,7 +51,6 @@ DEPEND="
 
 src_prepare() {
 	default
-	sed -i 's/ -Werror//' configure.ac || die
 	eautoreconf
 }
 
@@ -64,6 +63,8 @@ src_configure() {
 		--libdir="${EPREFIX}"/usr/lib
 		# Attempts to call python-exec directly otherwise.
 		--with-sphinx-python=${PYTHON}
+		# This disables -Werror, see also: https://github.com/hpc/charliecloud/pull/808
+		--enable-buggy-build
 	)
 	econf "${econf_args[@]}"
 }