From 15be69fe71a74c295fd158af856fb76dd78b17e5 Mon Sep 17 00:00:00 2001
From: orbea <orbea@riseup.net>
Date: Sun, 14 Jul 2024 17:43:24 -0700
Subject: app-crypt/qca: add 2.3.9

Signed-off-by: orbea <orbea@riseup.net>
---
 app-crypt/qca/Manifest         |   1 +
 app-crypt/qca/qca-2.3.9.ebuild | 119 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 120 insertions(+)
 create mode 100644 app-crypt/qca/qca-2.3.9.ebuild

(limited to 'app-crypt')

diff --git a/app-crypt/qca/Manifest b/app-crypt/qca/Manifest
index 6b18c45..dc6d605 100644
--- a/app-crypt/qca/Manifest
+++ b/app-crypt/qca/Manifest
@@ -1 +1,2 @@
 DIST qca-2.3.8.tar.xz 761340 BLAKE2B 04ec8d2fb9c2c00b04407828c549a4bb7d8bf6cda2f1071078dd446b8fc90c89872b2a4dc838bcb4eb34132545365be210c0043bde95c084901661a874600b34 SHA512 ddb410214e8264955c2bb8c68d018e3826cb8ec48f8cc7207c2aec1c36051dc0501455b5049eff927dcf354603c0646f86ca10f2cebebe87789b3fd07a993b68
+DIST qca-2.3.9.tar.xz 765256 BLAKE2B 6f8015f45c252d4991dce9154f270d7450b94ec40156e91d537fbdbc17969873689f324032ee24e3fa1c7205a41c6da2870375bfafa308cf82f266bc89da8081 SHA512 025ef203c66e413a9c93d7e0e5449d8a23fb6bb27b2f1c4f137173e33b8c17ff6dec794c8349b6b37ee9d7fffe23875a2cf7cf6592efc373f1aac9230f83aa06
diff --git a/app-crypt/qca/qca-2.3.9.ebuild b/app-crypt/qca/qca-2.3.9.ebuild
new file mode 100644
index 0000000..64af476
--- /dev/null
+++ b/app-crypt/qca/qca-2.3.9.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake kde.org multibuild out-of-source-utils qmake-utils
+
+DESCRIPTION="Qt Cryptographic Architecture (QCA)"
+HOMEPAGE="https://userbase.kde.org/QCA"
+SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="amd64 ~arm arm64 ~hppa ~loong ~ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="botan debug doc examples gcrypt gpg logger nss pkcs11 +qt5 qt6 sasl softstore +ssl test"
+REQUIRED_USE="|| ( qt5 qt6 )"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	botan? ( dev-libs/botan:3= )
+	gcrypt? ( dev-libs/libgcrypt:= )
+	gpg? ( app-crypt/gnupg )
+	nss? ( dev-libs/nss )
+	pkcs11? (
+		>=dev-libs/openssl-1.1
+		dev-libs/pkcs11-helper
+	)
+	qt5? ( >=dev-qt/qtcore-5.14:5 )
+	qt6? (
+		dev-qt/qtbase:6
+		dev-qt/qt5compat:6
+	)
+	sasl? ( dev-libs/cyrus-sasl:2 )
+	ssl? ( >=dev-libs/openssl-1.1:= )
+"
+DEPEND="${RDEPEND}
+	test? (
+		qt5? (
+			dev-qt/qtnetwork:5
+			dev-qt/qttest:5
+		)
+		qt6? ( dev-qt/qtbase:6[network] )
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen[dot]
+		virtual/latex-base
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.3.4-libressl.patch"
+	"${FILESDIR}/${PN}-disable-pgp-test.patch"
+)
+
+qca_plugin_use() {
+	echo -DWITH_${2:-$1}_PLUGIN=$(usex "$1")
+}
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt5) $(usev qt6) )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DQCA_FEATURE_INSTALL_DIR="${EPREFIX}$(${MULTIBUILD_VARIANT}_get_mkspecsdir)/features"
+			-DQCA_PLUGINS_INSTALL_DIR="${EPREFIX}$(${MULTIBUILD_VARIANT}_get_plugindir)"
+			$(qca_plugin_use botan)
+			$(qca_plugin_use gcrypt)
+			$(qca_plugin_use gpg gnupg)
+			$(qca_plugin_use logger)
+			$(qca_plugin_use nss)
+			$(qca_plugin_use pkcs11)
+			$(qca_plugin_use sasl cyrus-sasl)
+			$(qca_plugin_use softstore)
+			$(qca_plugin_use ssl ossl)
+			-DBUILD_TESTS=$(usex test)
+		)
+		if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
+				mycmakeargs+=( -DBUILD_WITH_QT6=ON )
+		else
+				mycmakeargs+=( -DBUILD_WITH_QT6=OFF )
+		fi
+		cmake_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake_src_compile
+	if use doc; then
+		multibuild_for_best_variant cmake_build doc
+	fi
+}
+
+src_test() {
+	mytest() {
+		local -x QCA_PLUGIN_PATH="${BUILD_DIR}/lib/qca"
+		cmake_src_test
+	}
+	multibuild_foreach_variant mytest
+}
+
+src_install() {
+	multibuild_foreach_variant cmake_src_install
+
+	if use doc; then
+		multibuild_for_best_variant run_in_build_dir dodoc -r apidocs/html
+	fi
+
+	if use examples; then
+		dodoc -r "${S}"/examples
+	fi
+}
-- 
cgit v1.2.3-65-gdbad