1 files changed, 40 insertions, 0 deletions
diff --git a/dev-python/pykeepass/pykeepass-4.0.0.ebuild b/dev-python/pykeepass/pykeepass-4.0.0.ebuild
new file mode 100644
index 000000000..0770c7d77
--- /dev/null
+++ b/dev-python/pykeepass/pykeepass-4.0.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library to interact with keepass databases (supports KDBX3 and KDBX4) "
+HOMEPAGE="https://github.com/libkeepass/pykeepass"
+SRC_URI="https://github.com/libkeepass/pykeepass/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/argon2-cffi-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/construct-2.10.54[${PYTHON_USEDEP}]
+	>=dev-python/future-0.18.2[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.5[${PYTHON_USEDEP}]
+	>=dev-python/pycryptodome-3.8.2[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/pykeepass-4.0.0-fix-tests-install.patch )
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+	# pycryptodomex to pycryptodome conversion
+	sed -i 's/Cryptodome/Crypto/g' pykeepass/kdbx_parsing/{common,twofish}.py || die
+}
+
+python_test() {
+	"${EPYTHON}" tests/tests.py -v || die
+}