From 0d0c23d17542bce3ff32dd64e9e9ff6aedff3f79 Mon Sep 17 00:00:00 2001
From: Peter Wilmott <p8952@gentoo.org>
Date: Fri, 16 May 2014 22:59:45 +0000
Subject: Version bump & drop jruby target.

Package-Manager: portage-2.2.8-r1/cvs/Linux x86_64
---
 dev-ruby/pdf-reader/pdf-reader-1.3.3.ebuild | 56 +++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-ruby/pdf-reader/pdf-reader-1.3.3.ebuild

(limited to 'dev-ruby/pdf-reader/pdf-reader-1.3.3.ebuild')

diff --git a/dev-ruby/pdf-reader/pdf-reader-1.3.3.ebuild b/dev-ruby/pdf-reader/pdf-reader-1.3.3.ebuild
new file mode 100644
index 000000000000..db3034727a5d
--- /dev/null
+++ b/dev-ruby/pdf-reader/pdf-reader-1.3.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/pdf-reader/pdf-reader-1.3.3.ebuild,v 1.1 2014/05/16 22:59:37 p8952 Exp $
+
+EAPI=5
+
+GITHUB_USER=yob
+
+USE_RUBY="ruby19 ruby20"
+
+RUBY_FAKEGEM_TASK_TEST="spec"
+
+RUBY_FAKEGEM_TASK_DOC="doc"
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG README.rdoc TODO"
+
+inherit ruby-fakegem
+
+DESCRIPTION="PDF parser conforming as much as possible to the PDF specification from Adobe"
+HOMEPAGE="http://github.com/yob/pdf-reader/"
+
+# We cannot use the gem distributions because they don't contain the
+# tests' data, we have to rely on the git tags.
+SRC_URI="http://github.com/${GITHUB_USER}/${PN}/tarball/v${PV} -> ${PN}-git-${PV}.tgz"
+RUBY_S="${GITHUB_USER}-${PN}-*"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "dev-ruby/afm
+	dev-ruby/ascii85
+	dev-ruby/hashery
+	dev-ruby/ttfunk
+	dev-ruby/ruby-rc4"
+
+# rspec is loaded even during doc generation, so keep it around :(
+ruby_add_bdepend ">=dev-ruby/rspec-2.1:2"
+
+all_ruby_prepare() {
+	# Remove bundler support
+	sed -i -e '/[Bb]undler/d' Rakefile spec/spec_helper.rb || die
+	epatch "${FILESDIR}"/${P}-Rakefile.patch
+	rm Gemfile || die
+
+	# Roodi is not yet available in CVS.
+	sed -i -e '/roodi/d' Rakefile || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc examples/* || die
+}
-- 
cgit v1.2.3-65-gdbad