blob: 195885bc108ddcd60cff203aac58aab3ab75ab18 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit systemd
MY_P="${P/_p/p}"
DESCRIPTION="Lightweight NTP server ported from OpenBSD"
HOMEPAGE="http://www.openntpd.org/"
SRC_URI="mirror://openbsd/OpenNTPD/${MY_P}.tar.gz"
LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 sparc x86"
IUSE="libressl selinux"
DEPEND="
!net-misc/ntp[-openntpd]
libressl? ( dev-libs/libressl:0= )"
RDEPEND="
${DEPEND}
acct-group/openntpd
acct-user/openntpd
selinux? ( sec-policy/selinux-ntp )"
S="${WORKDIR}/${MY_P}"
src_prepare() {
default
# fix /run path
sed -i 's:/var/run/ntpd:/run/ntpd:g' src/ntpctl.8 src/ntpd.8 || die
sed -i 's:LOCALSTATEDIR "/run/ntpd:"/run/ntpd:' src/ntpd.h || die
# fix ntpd.drift path
sed -i 's:/var/db/ntpd.drift:/var/lib/openntpd/ntpd.drift:g' src/ntpd.8 || die
sed -i 's:"/db/ntpd.drift":"/openntpd/ntpd.drift":' src/ntpd.h || die
# fix default config to use gentoo pool
sed -i 's:servers pool.ntp.org:#servers pool.ntp.org:' ntpd.conf || die
printf "\n# Choose servers announced from Gentoo NTP Pool\nservers 0.gentoo.pool.ntp.org\nservers 1.gentoo.pool.ntp.org\nservers 2.gentoo.pool.ntp.org\nservers 3.gentoo.pool.ntp.org\n" >> ntpd.conf || die
# disable constraint config if libressl not enabled
use libressl || sed -ie 's/^constraints/#constraints/g' ntpd.conf || die
}
src_configure() {
econf \
--with-privsep-user=openntpd \
--with-privsep-path=/var/lib/openntpd/chroot \
$(use_enable libressl https-constraint)
}
src_install() {
default
rm -r "${ED}"/var || die
newinitd "${FILESDIR}/${PN}.init.d-20080406-r6" ntpd
newconfd "${FILESDIR}/${PN}.conf.d-20080406-r6" ntpd
systemd_newunit "${FILESDIR}/${PN}.service-20080406-r4" ntpd.service
}
|
GitWeb
